セルの値に基づいてExcelワークシートの名前を変更する

Question

ウェブとスタックを検索しようとしました。しかし、私は有用な何かを見つけることができませんでした。私は、セル値に不正な文字が含まれていないときにワークシートの名前が変更される非常に単純なイベントを作成しようとしています。

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range) 

Target = Sh.Cells(1, 1) 
If InStr(Target, "\") > 0 Or IsEmpty(Target) = True _ 
    Or InStr(Target, "/") > 0 Or InStr(Target, "*") > 0 _ 
    Or InStr(Target, "[") > 0 Or InStr(Target, "]") > 0 _ 
    Or InStr(Target, ":") > 0 Or InStr(Target, "?") > 0 Then 
Else 
    Sh.Name = Target 
End If 

End Sub 

このように動作するはずです。A1の値にすべての有効な文字が含まれている場合は、シートの名前を変更します。それは本当に起こっていますが、シートの名前に他のセルに付けた値も変更されます。何かアドバイス？

Answer 1

は、この試してみて：

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range) 
    Dim ws As Worksheet, r As Range, s As String 

    Set ws = Target.Parent 
    Set r = Intersect(Target, ws.Range("A1")) 

    If r Is Nothing Then Exit Sub 

    s = r.Value 
    If InStr(s, "\") > 0 Or s = "" _ 
     Or InStr(s, "/") > 0 Or InStr(s, "*") > 0 _ 
     Or InStr(s, "[") > 0 Or InStr(s, "]") > 0 _ 
     Or InStr(s, ":") > 0 Or InStr(s, "?") > 0 Then 
    Else 
     Sh.Name = s 
    End If 
End Sub 

注：

コードは値を再使用するためにチェックしません。

Answer 2

私はあなたがIf..End Ifブロックにハードコードそれらにせずに無効な文字のリストを事前に定義することができますよう、以下の方法を好む：

Option Explicit 

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range) 

    Dim rngA1OfSheet As Range 
    Dim varInvalidChars As Variant 
    Dim varTest As Variant 
    Dim blnCheck1 As Boolean 
    Dim blnCheck2 As Boolean 

    Set rngA1OfSheet = Sh.Range("A1") 

    If Not Intersect(Target, rngA1OfSheet) Is Nothing Then 
     blnCheck1 = IsEmpty(rngA1OfSheet.Value) 

     varInvalidChars = Array("\", "/", "*", "[", "]", ":", "?") 
     blnCheck2 = False 
     For Each varTest In varInvalidChars 
      If InStr(1, rngA1OfSheet.Value, CStr(varTest), vbTextCompare) > 0 Then 
       blnCheck2 = True 
       Exit For 
      End If 
     Next 

     If Not blnCheck1 And Not blnCheck2 Then 
      Sh.Name = rngA1OfSheet.Value 
     End If 

    End If 


End Sub