VBAのアクセスがエラー91

Question

私はこのコード

Public Sub Production_UpdateStatus(ByVal lngProductionId As Long, _ 
            ByVal NewProductionStatus As eProductionStatus)  
Dim oDb As DAO.Database 
Dim oRst As DAO.Recordset 
Dim StrSql As String 
Dim strProductionStatus As String 

On Error GoTo Err_Infos 

GetCurrentProductionStatusString NewProductionStatus, strProductionStatus 

Set oDb = CurrentDb 

'Mise a jour du staut de production 
StrSql = "UPDATE tProduction SET tProduction.Statut= '" & strProductionStatus & "'" _ 
      & " WHERE (tProduction.IdProduction=" & lngProductionId & ");" 
oDb.Execute StrSql 

'Fermeture des connexions 
oRst.Close 
oDb.Close 
Set oDb = Nothing 
Set oRst = Nothing 

Exit_currentSub: 
    Exit Sub 

Err_Infos: 
    MsgBox "Erreur #" & Err.Number & " : " & Err.Description 
    Resume Exit_currentSub 

End Sub 

にこのコードの作業を実行しますが、エラーに私に

それを設定していない91

オブジェクト変数またはWithブロック変数を与えることを試みます次のSQLクエリを生成します。

UPDATE tProduction SET tProduction.Statut= 'Nouvelle' WHERE (tProduction.IdProduction=2); 

私は直接クエリをテストするとき、私はエラーがありません。このエラーを取り除く手助けをしてもらえますか？

ありがとうございました

Answer 1

で初期化されていないレコードセットオブジェクトを閉じています。アクションクエリを実行するため、レコードセットは不要であり、以前のコードバージョンのまま残っている可能性があります。同じノートで

、あなたはSQLクエリにリテラル値を渡しているので、連結と引用エンクロージャを回避するDAO QueryDef parametersでパラメータ設定を検討しが：

Dim oDb As DAO.Database, qdef As DAO.QueryDef 
Dim StrSql As String, strProductionStatus As String 

GetCurrentProductionStatusString NewProductionStatus, strProductionStatus 

Set oDb = CurrentDb 

StrSql = "PARAMETERS strProductionStatusParam Text(255), lngProductionIdParam Long;" _ 
      & " UPDATE tProduction SET tProduction.Statut = [strProductionStatusParam]" _ 
      & " WHERE (tProduction.IdProduction = [lngProductionIdParam]);" 

Set qdef = oDb.CreateQueryDef("", StrSql) 

qdef!strProductionStatusParam = strProductionStatus 
qdef!lngProductionIdParam = lngProductionId 

qdef.Execute dbFailOnError 

Set qdef = Nothing 
Set oDb = Nothing 

Answer 2

oRst関連のコード行を削除してみてください。この変数は初期化されず、使用されません。