バッチ内のデータの追加

Question

これはログオンスクリプトの一部です。スクリプトは、ユーザーが自分のコンピュータにログインするたびに実行されます。スクリプトが実行する必要があるのは、実行されるたびに同じファイルにログを記録することですが、データを上書きする必要はありません。私はそれを下の行に追加したい。

if not exist "C:\Windows\LogonScript" mkdir C:\Windows\LogonScript" 
(echo Username: %USERNAME% 
systeminfo | findstr /c:"Host Name" 
systeminfo | findstr /c:"Domain" 
systeminfo | findstr /c:"OS Name" 
systeminfo | findstr /c:"System Manufacturer" 
systeminfo | findstr /c:"System Model" 
systeminfo | findstr /c:"System type" 
systeminfo | findstr /c:"Total Physical Memory" 
ipconfig | findstr IPv4 
echo Hard Drive Information: 
wmic LOGICALDISK where drivetype=3 get caption,size,FreeSpace) > C:\Windows\LogonScript\%COMPUTERNAME%.txt 

xcopy /s C:\Windows\LogonScript\%COMPUTERNAME%.txt \\ess\Home\cgoodwin\Scripts 

exit 

Answer 1

次のスニペットは、私は私のコメントで与えた答えを使用して追加します：私は、私がこれまで持っている、これはすべてで、それを考え出す問題を抱えています。さらにそれは、かなり高速になり（本当に遅いシステムのシステム情報コマンドの単一のインスタンスを実行することによって）必要があります。

If Not Exist "C:\Windows\LogonScript\" MD "C:\Windows\LogonScript" 
(Echo UserName:     %UserName% 
SystemInfo|FindStr/IL /C:"Host Name:" /C:"Domain:" /C:"OS Name:"^ 
/C:"System Manufacturer:" /C:"System Model:" /C:"System Type:"^ 
/C:"Total Physical Memory:" 
For /F "Tokens=2 Delims=:" %%A In ('IPConfig^|Find "IPv4"' 
) Do Echo=IP Address:    %%A 
Echo(
Echo Logical Disk Information: 
WMIC LogicalDisk Where DriveType=3 Get Caption, Size, FreeSpace|More 
)>>"C:\Windows\LogonScript\%ComputerName%.txt"