- ここ</p> <pre><code>dispatchEvent(new Event(GOT_RESULT,result)); </code></pre> <p>のようなAS3

Question

いずれかが私にそれに接続されているオブジェクトとactionscript3にイベントをディスパッチする方法についての簡単な例を与えることができ、resultは、そのオブジェクトでありますイベントと一緒に過ごしたい。

Answer 1

イベントを介してオブジェクトを渡す場合は、カスタムイベントを作成する必要があります。コードはこのようなものでなければなりません。

public class MyEvent extends Event 
{ 
    public static const GOT_RESULT:String = "gotResult"; 

    // this is the object you want to pass through your event. 
    public var result:Object; 

    public function MyEvent(type:String, result:Object, bubbles:Boolean=false, cancelable:Boolean=false) 
    { 
     super(type, bubbles, cancelable); 
     this.result = result; 
    } 

    // always create a clone() method for events in case you want to redispatch them. 
    public override function clone():Event 
    { 
     return new MyEvent(type, result, bubbles, cancelable); 
    } 
} 

は、その後、あなたは、このように上記のコードを使用することができます。

dispatchEvent(new MyEvent(MyEvent.GOT_RESULT, result)); 

そして、あなたが必要なこのイベントのために聞きます。

addEventListener(MyEvent.GOT_RESULT, myEventHandler); 
// more code to follow here... 
protected function myEventHandler(event:MyEvent):void 
{ 
    var myResult:Object = event.result; // this is how you use the event's property. 
} 

Answer 2

正しく設計されていれば、イベントにオブジェクトを渡す必要はありません。
代わりに、ディスパッチクラスにpublic varを作成する必要があります。

public var myObject:Object; 

// before you dispatch the event assign the object to your class var 
myObject = ....// whatever it is your want to pass 
// When you dispatch an event you can do it with already created events or like Tomislav wrote and create a custom class. 

// in the call back just use currentTarget 
public function myCallBackFunction(event:Event):void{ 

    // typecast the event target object 
    var myClass:myClassThatDispatchedtheEvent = event.currentTarget as myClassThatDispatchedtheEvent 
    trace(myClass.myObject)// the object or var you want from the dispatching class. 

Answer 3

この投稿は少し古いですが、それが誰かを助けることができるならば、あなたはとても似によってDataEventクラスを使用することができます。

dispatchEvent(new DataEvent(YOUR_EVENT_ID, true, false, data)); 

Documentation