テキストファイルをループする

Question

テキストファイルに情報を抽出してループに入れる必要があります。簡単にするために、最初の行が人物であり、2番目の行が好みの色であると仮定してください。

テキストファイルは次のようになります。

tim 
red 
sarah 
blue and yellow 
sam 
green 

私は、エコー出力は次のようになりたいのですが：

tim likes red 
sarah likes blue and yellow 
sam likes green 

私はこれまでのコードを持っていることは以下の通りです：

for /f "tokens=1 delims=" %%Name %%color in (C:\textfile.txt) do echo %%Name likes %%color 

Answer 1

@echo off 
setlocal enabledelayedexpansion 
set x=0 
for /f "delims=" %%a in (t.txt) do (
    set /a "x=(x+1) %% 2" 
    if !x! == 1 set name=%%a 
    if !x! == 0 echo !name! likes %%a. 
) 

私は、次のオプションを参照してくださいあなたの仕事のために

Answer 2

：

1. for /Fループや設定を使用して、特定の名前に関連付けられた色を待つために、他のすべての反復中に交互に変数（NAME）をクリア：

   @echo off 
   setlocal EnableDelayedExpansion 
   set "NAME=" 
   for /F "usebackq tokens=*" %%L in ("textfile.txt") do (
       if defined NAME (
        echo !NAME! likes %%L 
        set "NAME=" 
       ) else (
        set "NAME=%%L" 
       ) 
   ) 
   endlocal 
   

2. 用いてfor /Lループを使用し、反復ごとに一度に2行を読み取り、予め行数の半分を決定します入力のリダイレクト（<）：

   @echo off 
   setlocal EnableDelayedExpansion 
   for /F %%C in ('^< "textfile.txt" find /C /V ""') do set /A "HALF=%%C/2" 
   
   < "textfile.txt" (
       for /L %%I in (1,1,%HALF%) do (
        set /P NAME= 
        set /P COLOUR= 
        echo !NAME! likes !COLOUR! 
       ) 
   ) 
   endlocal