Inno Setupの - 私は（InnoCallback DLLライブラリで）このコードを使用しようとしています確定ページに

Question

を右から制御ロールをアニメーション：

[Code] 

var 
    MainPanelAnimated: Boolean; 
    AnimationTimer: LongWord; 

procedure AnimationTimerProc(
    H: LongWord; Msg: LongWord; IdEvent: LongWord; Time: LongWord); 
var 
    L: Integer; 
begin 
    L := WizardForm.MainPanel.Left + ScaleX(5); 
    if L > 0 then 
    begin 
    L := 0; 
    KillTimer(0, AnimationTimer); 
    end; 
    WizardForm.MainPanel.Left := L; 
end; 

procedure CurPageChanged(CurPageID: Integer); 
var 
    HoverTimerCallback: LongWord; 
begin 
    if WizardForm.OuterNotebook.ActivePage = WizardForm.InnerPage then 
    begin 
    if not MainPanelAnimated then 
    begin 
     HoverTimerCallback := WrapTimerProc(@AnimationTimerProc, 4); 
     AnimationTimer := SetTimer(0, 0, 5, HoverTimerCallback); 
     WizardForm.MainPanel.Left := -WizardForm.MainPanel.Width; 
     MainPanelAnimated := True; 
    end; 
    end; 
end; 

How to animate a control roll out in Inno Setup（マーティンPrikrylの答え）から、表示するには同じ効果ですが、右から左へと設定の確定ページにあります。これを行う方法？

Answer 1

CurPageChangedにCurPageIDを使用して、アニメーションを表示するページを選択します。

[Files] 
Source: InnoCallback.dll; Flags: dontcopy 

[Code] 

type 
    TTimerProc = procedure(H: LongWord; Msg: LongWord; IdEvent: LongWord; Time: LongWord); 

function SetTimer(hWnd: longword; nIDEvent, uElapse: LongWord; lpTimerFunc: LongWord): 
    LongWord; external 'SetTimer@user32.dll stdcall'; 
function KillTimer(hWnd, nIDEvent: LongWord): LongWord; 
    external 'KillTimer@User32.dll stdcall'; 

function WrapTimerProc(Callback: TTimerProc; ParamCount: Integer): LongWord; 
    external 'wrapcallback@files:innocallback.dll stdcall'; 

var 
    AnimationTimer: LongWord; 

procedure AnimationTimerProc(
    H: LongWord; Msg: LongWord; IdEvent: LongWord; Time: LongWord); 
var 
    L: Integer; 
begin 
    L := WizardForm.MainPanel.Left - ScaleX(5); 
    if L < 0 then 
    begin 
    L := 0; 
    KillTimer(0, AnimationTimer); 
    end; 
    WizardForm.MainPanel.Left := L; 
end; 

procedure CurPageChanged(CurPageID: Integer); 
var 
    HoverTimerCallback: LongWord; 
begin 
    if CurPageID = wpReady then 
    begin 
    HoverTimerCallback := WrapTimerProc(@AnimationTimerProc, 4); 
    AnimationTimer := SetTimer(0, 0, 5, HoverTimerCallback); 
    WizardForm.MainPanel.Left := WizardForm.MainPanel.Width; 
    end; 
end; 

コードにはInnoTools InnoCallback DLL libraryが使用されています。