新しいCMDウィンドウでCMDとPingのIPV4変数を取得する方法

Question

ここには考えがあります。 私はIPv4などのCmdから変数を取得し、新しいウィンドウでpingできるようにしようとしています。

コマンドを実行してそのコマンドの特定の部分を取得し、新しいコマンドラインで新しいバイラブルとして入力できるようにすることで、アクションを実行できるロジックは何でしょうか。

もう一つの例：

1. は、コンピュータ名を検索します。
2. コンピュータ名の最後にある番号にコマンドを実行します。

私は現在、Visual Basicソフトウェアをダウンロードしていますが、必要な言語かもしれないが、非常に混乱しているようです。

誰でも私が使用できるものについての基本的な考え方はありますか、これの例がありますか？

Answer 1

あなたはそのような何か試すことができます。pingで

@Echo off 
Color 0A & Mode con cols=80 lines=15 
Title How to grab IPv4 
::********************************** 
::Method1 
::********************************** 
echo( 
echo Method 1 with arp -a 
echo( 
For /f "tokens=2 delims= " %%a in ('arp -a ^|findstr /i "Interface"') do (set IP=%%a) 
Echo The Local IPv4 adress is : %IP% 
pause 
Cls 
Call:PingHost %IP% 
pause 
::********************************** 
::Method2 
::********************************** 
cls 
echo( 
echo Method 2 with ipconfig 
for /f "tokens=1-2 delims=:" %%a in ('ipconfig^|find "IPv4"') do (
    set ip=%%b 
) 
set ip=%ip:~1% 
echo( 
echo The Local IPv4 adress is : %ip% 
pause 
Cls 
Call:PingHost %IP% 
pause 
::********************************** 
::Method3 by Stephan 
::********************************** 
cls 
echo( 
echo Method 3 with %%computername%% = %computername% 
for /f "tokens=2 delims=[]" %%i in ('ping -4 -n 1 %computername%') do set ip=%%i 
echo( 
echo The Local IPv4 adress is : %ip% 
pause 
Cls 
Call:PingHost %IP% 
Pause 
exit 
::********************************** 
:Pinghost 
Start "%1" Ping %1 
exit /b 
::**********************************