一部のグラフでのみ有効なVBAコード

Question

ワークシートのすべてのグラフでセカンダリ軸の範囲を更新するためのVBAコードは、一部のグラフでのみ機能します。マクロを実行すると、オブジェクト '_Chart'の "Method 'Axes'メッセージが表示され、そのワークシート上の一部のグラフのみが更新されます。ここで何が問題なの？

Sub Macro1() 

Dim objChart As ChartObject, lower As Double, upper As Double 

lower = Application.InputBox(prompt:="Enter lower bound", Type:=1) 
upper = Application.InputBox(prompt:="Enter upper bound", Type:=1) 

For Each objChart In Sheets("Summary").ChartObjects 
    With objChart.Chart.Axes(xlValue, xlSecondary) 
     .MinimumScale = lower 
     .MaximumScale = upper 
    End With 
Next objChart 

End Sub 

Answer 1

ChartObjectにセカンダリ軸がない場合は、エラーになります。私はあなたの正確なエラーを再現する方法を見つけ出すことができませんでしたが、私はa commentに言ったように、手順を抽出し、実行時エラーを処理する少なくともヘルプには、すべてのチャートの問題を診断し、ループの反復処理を行う必要があります。

Public Sub UpdateSummarySheetChartAxes() 

    Dim lower As Double 
    lower = Application.InputBox(prompt:="Enter lower bound", Type:=1) 

    Dim upper As Double   
    upper = Application.InputBox(prompt:="Enter upper bound", Type:=1) 

    Dim objChart As ChartObject 
    For Each objChart In Sheets("Summary").ChartObjects 
     UpdateChartAxes objChart, lower, upper 
    Next objChart 

End Sub 

Private Sub UpdateChartAxes(ByVal objChart As ChartObject, ByVal lower As Double, ByVal upper As Double) 
    On Error GoTo CleanFail 
    With objChart.Chart.Axes(xlValue, xlSecondary) 
     .MinimumScale = lower 
     .MaximumScale = upper 
    End With 
CleanExit: 
    Exit Sub 
CleanFail: 
    Debug.Print "Failed updating axes for chart '" & objChart.Name & "'. Message: " & Err.Description 
    Resume CleanExit 
End Sub