あるディレクトリから別のディレクトリに最新のファイルをバッチコピーし、名前を変更して上書きします。

Question

Windowsのバッチファイルを使用して、ディレクトリ内の最新のファイルを別のディレクトリにコピーする方法が見つかりました。しかし、コピーしたファイルの名前を変更して古いファイルを上書きする方法を理解するのに助けてください。

@echo off 
set source="D:\Backup" 
set target="D:\tmp" 

FOR /F "delims=" %%I IN ('DIR %source%\*.csv /A:-D /O:-D /B') DO COPY %source%\"%%I" %target% & echo %%I & GOTO :END 
:END 

ソースバックアップフォルダには、日付と時刻が追加された増分バックアップが含まれています。私は結果が一定の名前、例えばraw.csvと言いたいので、Excelでそれを操作することができます。

ありがとうございました！

Answer 1

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    set "source=D:\Backup" 
    set "target=D:\tmp" 

    FOR /F "delims=" %%I IN (' 
     DIR "%source%\*.csv" /A-D /O-D /B 
    ') DO COPY "%source%\%%I" "%target%\raw.csv" & echo %%I & GOTO :END 

:END 

コメントとして、コピー操作にターゲット名を含めるだけです。

また、変数の定義も変更しました。良い理由がある場合を除き、パスを使って作業する場合は、ではなくで、変数値に引用符を含めてください（後で扱うのは難しい）。代入を引用するだけで（特殊文字や最終スペースでの問題を防ぐため）、後で、必要に応じてファイルシステム参照を引用します。

set "source=d:\backup" 
    ^................^ 

set "target=D:\tmp" 
    ^.............^ 

dir "%source%\*.csv" 
    ^..............^ 

COPY "%source%\%%I" "%target%\raw.csv" 
    ^............^ ^................^