movieclipの別のインスタンスに続く行

Question

私は十字線のxとyの位置にlineToを設定しているので、私の線が私の十字線に沿っていないので、別のインスタンス（十字線）

swfファイルはここにhttp://megaswf.com/filelinks/1156538、

私は行がこれらあるんコードです。

_crossはクロスヘアのインスタンスであり、rodhitは私が釣竿の「先端」に付けたsシンボルのインスタンスなので、moveToは含まれませんでした。ここ

addEventListener(Event.ENTER_FRAME, crossLoop); 

public function crossLoop(e:Event):void 
     { 

      //calculations, distance, angle etc 
      if (_cross != null) 
      { 
      var a:Number = _cross.x- x; 
      var b:Number = _cross.y - y; 
      rodhit.graphics.lineTo(_cross.x, _cross.y); 
      var angRad:Number = Math.atan2(b, a); 
      var angDeg:Number = (angRad * 180/Math.PI); 
      //trace(angDeg); 

      rotation = (angDeg); 
      if (angDeg > -10) 
       rotation = -10; 
      if (angDeg < -170) 
       rotation = -170 


      } 
     } 

Answer 1

あなたがこれを行うことができます方法の例です：あなたがアップロードしたSWFは私のために再生されないhttp://wonderfl.net/c/6K52

package 
{ 
    import flash.display.Shape; 
    import flash.events.MouseEvent; 
    import flash.events.Event; 
    import flash.display.Sprite; 
    public class FlashTest extends Sprite { 
     private var _cross:Sprite; 
     private var _line:Shape; 
     public function FlashTest() { 
      _cross = new Sprite(); 
      _cross.graphics.beginFill(0xFF0000, 1); 
      _cross.graphics.drawCircle(0, 0, 20); 
      addChild(_cross); 

      _line = new Shape(); 
      _line.x = 200; 
      _line.y = 30; 
      addChild(_line); 

      stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove); 
      addEventListener(Event.ENTER_FRAME, onEnterFrame); 
     } 

     private function onMouseMove(evt:MouseEvent):void 
     { 
      _cross.x = stage.mouseX; 
      _cross.y = stage.mouseY; 
     } 

     private function onEnterFrame(evt:Event):void 
     { 
      _line.graphics.clear(); 
      _line.graphics.lineStyle(2, 0x000000, 1); 
      _line.graphics.lineTo(_cross.x - _line.x, _cross.y - _line.y); 
     } 
    } 
}