Cython - stdlibを使って<random>

Question

私はC++ライブラリを乱数ジェネレータを生成する親と均等に分布する乱数を生成するために使用する子を使ってcythonで動作させようとしています。コードが正しくコンパイルものの

[rnd.pyx] 
cdef extern from "<random>" namespace "std": 
    cdef cppclass mt19937: 
     mt19937() except + 
     mt19937(unsigned int) except + 
    cdef cppclass uniform_real_distribution[T]: 
     uniform_real_distribution() 
     uniform_real_distribution(double, double) 
     T operator()(mt19937) 

cdef class Child: 
    cdef mt19937 *rng 
    cdef uniform_real_distribution[double] uniform 
    def __cinit__(Child self): 
     cdef unsigned int seed = 123154654 
     self.rng = NULL 
     self.uniform = uniform_real_distribution[double](0.,1.) 
    cdef set_rng(Child self, mt19937 rng): 
     self.rng = &rng 
    def gen_uniform(self): 
     return self.uniform(self.rng[0]) 

cdef class Parent: 
    cdef mt19937 rng 
    cdef public list children 
    def __cinit__(Parent self): 
     cdef unsigned int seed = 123154654 
     self.rng = mt19937(seed) 
     self.children = [] 
    cpdef make_child(Parent self): 
     child = Child() 
     child.set_rng(self.rng) 
     self.children.append(child) 

[rnd.pyxbuild] 
import os 
from distutils.extension import Extension 
dirname = os.path.dirname(__file__) 
def make_ext(modname, pyxfilename): 
    return Extension(
     name=modname, 
     sources=[pyxfilename], 
     extra_compile_args=["-std=c++11"], 
     language="c++", 
     include_dirs=[dirname] 
    ) 

[test.py] 
import pyximport 
pyximport.install() 

from rnd import Child, Parent 

p = Parent() 

for i in range(300): 
    p.make_child() 
for child in p.children: 
    a = child.gen_uniform() 
    print(a) 

しかし、gen_uniform関数の出力は、私が期待するものは本当にありません：test.pyコードは最初0.941197317223、永遠に続い0.743410046664生成します。私はChild.gen_uniformを変更し、それを再現するために管理していないのに

また、私はかつて大きな乱数（あまり）を取得するために管理している私からrngポインタを渡し、より複雑なコードでは最終的に1.0

私は普通の数字、ゼロ、1より大きい数値、次にセグメント化の誤りを得る。

誰かが問題の原因を教えてもらえますか？

Answer 1

あなたのコード

cdef set_rng(Child self, mt19937 rng): 
    self.rng = &rng 

は、それに渡された乱数ジェネレータをコピーすることによって、一時的な乱数生成器（rng）を作成します。それは一時的なものへのポインタを受け取り、一時的に関数の終わりに存在しなくなり、ポインタが無効になります。あなたはおそらく行うには何を意味

は次のとおりです。

cdef set_rng(Child self, mt19937& rng): 
    self.rng = &rng 

（すなわち、参照することにより、それを渡します）。これは、ParentがChildと、すべてのChildが指すポインタを保持する乱数ジェネレータの両方を所有しているという事実に依存しています。したがって、それらはすべて同じ寿命を有する。これが真実でないなら、あなたは困っており、このスキームを考え直す必要があります（おそらく共有ポインタを考慮していますか？）。