DelphiのWindowsを使用してファイル情報を取得するapi

Question

ファイルがフォルダであるかどうかを取得するためにPItemIDListからDelphiとWindows APIを使用することは可能ですか？このコードスニペットを使用すると、ファイルの名前だけを取得できます。相対PIDL用

procedure TMain.FolderMonitorFileChange(aSender: TObject; aPIDL: PItemIDList); 
var 
    FileInfo : SHFILEINFOW; 
begin 
    SHGetFileInfo(LPCTSTR(aPIDL), 0 , FileInfo, SizeOf(FileInfo), SHGFI_PIDL or SHGFI_DISPLAYNAME or SHGFI_TYPENAME or SHGFI_ATTRIBUTES); 
    ShowMessage('File change notification: ' + FileInfo.szDisplayName + ' ' + FileInfo.szTypeName); 
end; 

おかげ

Answer 1

、あなたはPIDLの親フォルダのIShellFolderインタフェースを取得し、その後IShellFolder::GetAttributesOf()方法にPIDLを渡すことができます。絶対PIDL用

function IsFolder(Parent: IShellFolder; aChildPIDL: PItemIDList): Boolean; 
var 
    Attrs: SFGAOF; 
begin 
    Result := Succeeded(Parent.GetAttributesOf(1, @aChildPidl, @Attrs)) 
    and (Attrs and SFGAO_FOLDER <> 0); 
end; 

、あなたはいくつかの異なるオプションがあります。

• はIShellFolder::GetAttributesOf()を呼び出し、その後、相対PIDLに変換し、その親フォルダのIShellFolderを取得するためにSHBindToParent()にPIDLを渡します。

  function IsFolder(aPIDL: PItemIDList): Boolean; 
  var 
      Parent: IShellFolder; 
      Child: PItemIDList; 
      Attrs: SFGAOF; 
  begin 
      Result := Succeeded(SHBindToParent(aPidl, IShellFolder, @Parent, @Child)) 
      and Succeeded(Parent.GetAttributesOf(1, @Child, @Attrs)) 
      and (Attrs and SFGAO_FOLDER <> 0); 
  end; 
  

• はSHGFI_PIDLフラグを使用SHGetFileInfo()にPIDLを渡します。アイテムの属性を要求するには、SHGFI_ATTRIBUTESフラグを有効にします。

  function IsFolder(aPIDL: PItemIDList): Boolean; 
  var 
      FileInfo : SHFILEINFO; 
  begin 
      Result := (SHGetFileInfo(LPCTSTR(aPIDL), 0, @FileInfo, SizeOf(FileInfo), SHGFI_PIDL or SHGFI_ATTRIBUTES) <> 0) 
      and (FileInfo.dwAttributes and SFGAO_FOLDER <> 0); 
  end; 
  

• はそれのためIShellItemインタフェースを取得するためにSHCreateItemFromIDList()にPIDLを渡し、そのIShellItem::GetAttributes()を呼び出します。

  function IsFolder(aPIDL: PItemIDList): Boolean; 
  var 
      Item: IShellItem; 
      Attrs: SFGAOF; 
  begin 
      Result := Succeeded(SHCreateItemFromIDList(aPidl, IShellItem, @Item)) 
      and Succeeded(Item.GetAttributes(SFGAO_FOLDER, @Attrs)) 
      and (Attrs and SFGAO_FOLDER <> 0); 
  end;