pl/sqlクエリブロックに変数値を渡しました

Question

1つの問題が発生しました。

PL/SQLブロックが値

p_user_id := '101,102,103'; 

以下に設定した値変数p_user_idのVARCHAR（50）

が含まれている、私はPL/SQLブロックに以下のようなクエリを持っている...あなたの専門知識を必要としてください

select Count(*) into v_count 
from users 
where user_id not in (p_user_id); 

このPL/SQLブロックを呼び出すたびに、v_countの値は同じです（つまり、ユーザー表のレコードの総数は同じです）。 Not In節が正しく機能していません。助けてください。

Answer 1

使うLIKE文字列の比較：

DECLARE 
    p_user_id VARCHAR2(200) := '101,102,103'; 
    v_count INT; 
BEGIN 
    SELECT Count(*) 
    INTO v_count 
    FROM users 
    WHERE ',' || p_user_id || ',' NOT LIKE '%,' || user_id || ',%'; 
END; 
/

使用してコレクション：

CREATE OR REPLACE TYPE intlist IS TABLE OF INT; 
/

DECLARE 
    p_user_id INTLIST := INTLIST(101, 102, 103); 
    v_count INT; 
BEGIN 
    SELECT Count(*) 
    INTO v_count 
    FROM users 
    WHERE user_id NOT MEMBER OF p_user_id; 
END; 
/

Answer 2

user_idの値が '101,102,103'であるusersテーブルに行がありません。

文字列を別々の値のセットに分割する場合は、not in式で文字列を使用する以外にも、少し以上の作業を行う必要があります。

いくつかの可能なアプローチ：

declare 
    p_csvlist varchar2(100) := '2002, 7369, 7499, 7902, 7934'; 
    v_count integer; 
begin 
    select count(*) into v_count 
    from emp e 
    where e.empno in 
      (select extractvalue(xt.column_value,'e') 
      from table(xmlsequence 
        (extract 
        (xmltype('<coll><e>' || replace(p_csvlist,',','</e><e>') || '</e></coll>') 
        , '/coll/*'))) xt); 

    dbms_output.put_line(v_count || ' rows'); 
end; 

またはこの

declare 
    p_csvlist varchar2(100) := '2002, 7369, 7499, 7902, 7934'; 
    v_count integer; 
begin 
    select count(*) into v_count 
    from emp e 
    where e.empno in 
      (select regexp_substr(p_csvlist, '[^,]+',1,rownum) 
      from dual 
      connect by rownum <= length(p_csvlist) - length(replace(p_csvlist,','))); 

    dbms_output.put_line(v_count || ' rows'); 
end; 

または本（数値のみで動作します）：

declare 
    p_csvlist varchar2(100) := '2002, 7369, 7499, 7902, 7934'; 
    v_count integer; 
begin 
    select count(*) into v_count 
    from emp e 
    where e.empno in 
      (select to_number(xt.column_value) 
      from xmltable(p_csvlist) xt); 

    dbms_output.put_line(v_count || ' rows'); 
end; 

例としては、私のよくある質問の記事からです： www.williamrobertson.net/documents/comma-separated.html

Answer 3

あなたが「doesnの句でのOracle自体

DECLARE 
     p_user_id sys.DBMS_DEBUG_VC2COLL := sys.DBMS_DEBUG_VC2COLL(101, 102, 103); 
     v_count INT; 
    BEGIN 
     SELECT Count(*) 
     INTO v_count 
     FROM users 
     WHERE user_id not in(select * from table(p_user_id)); 
    END; 
    /