1. ホーム
  2. 質問と答え
  3. MD5と異なるDelphiの結果ハッシュ関数

MD5と異なるDelphiの結果ハッシュ関数

2017-01-26 18 views
0

私はDelphi Berlinと連携しています。
私は古いプロジェクトを移行しようとしています。
md5ユニットの古い関数RivestStrを新しいMD5Hashで置き換えることはできません。
動作をテストするために、私は2つのボタンと3つの編集で簡単なプロジェクトを作成します。MD5と異なるDelphiの結果ハッシュ関数

私の問題は、この2つの機能が異なる結果であるという事実です。
と私はRivestStrと同じ結果を与えるためにMD5Hashを作る方法がわかりません。

uses IdHashMessageDigest, idHash 

function MD5Hash(Value : String) : String; 
var workHash : TIdHashMessageDigest5; 
begin 
    try 
    workHash := TIdHashMessageDigest5.Create; 
    Result := workHash.HashStringAsHex(Value); 
    finally 
    FreeAndNil(workHash); 
    end; 
end; 

procedure TForm5.Button1Click(Sender: TObject); 
begin 
    edResult.Text := MD5Hash(edPass.Text); 
end; 

procedure TForm5.Button2Click(Sender: TObject); 
begin 
    edRivest.Text := RivestStr(edPass.Text); 
end; 

unit md5; 

interface 

uses Windows, SysUtils, Classes; 



type 
    MD5Count = array[0..1] of DWORD; 
    MD5State = array[0..3] of DWORD; 
    MD5Block = array[0..15] of DWORD; 
    MD5CBits = array[0..7] of Byte; 
    MD5Digest = array[0..15] of Byte; 
    MD5Buffer = array[0..63] of Byte; 
    MD5Context = record 
    State: MD5State; 
    Count: MD5Count; 
    Buffer: MD5Buffer; 
    end; 

procedure MD5Init(var Context: MD5Context); 
procedure MD5Update(var Context: MD5Context; Input: pChar; Length: longword); 
procedure MD5Final(var Context: MD5Context; var Digest: MD5Digest); 

function MD5String(M: string): MD5Digest; 
function MD5File(N: string): MD5Digest; 
function MD5Print(D: MD5Digest): string; 
function MD5Match(D1, D2: MD5Digest): Boolean; 

function RivestStr(Str: string): string; 
function RivestFile(FileName: string): string; 


var 

    PADDING: MD5Buffer = (
    $80, $00, $00, $00, $00, $00, $00, $00, 
    $00, $00, $00, $00, $00, $00, $00, $00, 
    $00, $00, $00, $00, $00, $00, $00, $00, 
    $00, $00, $00, $00, $00, $00, $00, $00, 
    $00, $00, $00, $00, $00, $00, $00, $00, 
    $00, $00, $00, $00, $00, $00, $00, $00, 
    $00, $00, $00, $00, $00, $00, $00, $00, 
    $00, $00, $00, $00, $00, $00, $00, $00); 

implementation 






function F(x, y, z: DWORD): DWORD; 
begin 
    Result := (x and y) or ((not x) and z); 
end; 

function G(x, y, z: DWORD): DWORD; 
begin 
    Result := (x and z) or (y and (not z)); 
end; 

function H(x, y, z: DWORD): DWORD; 
begin 
    Result := x xor y xor z; 
end; 

function I(x, y, z: DWORD): DWORD; 
begin 
    Result := y xor (x or (not z)); 
end; 

procedure rot(var x: DWORD; n: BYTE); 
begin 
    x := (x shl n) or (x shr (32 - n)); 
end; 

procedure FF(var a: DWORD; b, c, d, x: DWORD; s: BYTE; ac: DWORD); 
begin 
    inc(a, F(b, c, d) + x + ac); 
    rot(a, s); 
    inc(a, b); 
end; 

procedure GG(var a: DWORD; b, c, d, x: DWORD; s: BYTE; ac: DWORD); 
begin 
    inc(a, G(b, c, d) + x + ac); 
    rot(a, s); 
    inc(a, b); 
end; 

procedure HH(var a: DWORD; b, c, d, x: DWORD; s: BYTE; ac: DWORD); 
begin 
    inc(a, H(b, c, d) + x + ac); 
    rot(a, s); 
    inc(a, b); 
end; 

procedure II(var a: DWORD; b, c, d, x: DWORD; s: BYTE; ac: DWORD); 
begin 
    inc(a, I(b, c, d) + x + ac); 
    rot(a, s); 
    inc(a, b); 
end; 

procedure Encode(Source, Target: pointer; Count: longword); 
var 
    S: PByte; 
    T: PDWORD; 
    I: longword; 
begin 
    S := Source; 
    T := Target; 
    for I := 1 to Count div 4 do begin 
    T^ := S^; 
    inc(S); 
    T^ := T^ or (S^ shl 8); 
    inc(S); 
    T^ := T^ or (S^ shl 16); 
    inc(S); 
    T^ := T^ or (S^ shl 24); 
    inc(S); 
    inc(T); 
    end; 
end; 

procedure Decode(Source, Target: pointer; Count: longword); 
var 
    S: PDWORD; 
    T: PByte; 
    I: longword; 
begin 
    S := Source; 
    T := Target; 
    for I := 1 to Count do begin 
    T^ := S^ and $ff; 
    inc(T); 
    T^ := (S^ shr 8) and $ff; 
    inc(T); 
    T^ := (S^ shr 16) and $ff; 
    inc(T); 
    T^ := (S^ shr 24) and $ff; 
    inc(T); 
    inc(S); 
    end; 
end; 

procedure Transform(Buffer: pointer; var State: MD5State); 
var 
    a, b, c, d: DWORD; 
    Block: MD5Block; 
begin 
    Encode(Buffer, @Block, 64); 
    a := State[0]; 
    b := State[1]; 
    c := State[2]; 
    d := State[3]; 
    FF (a, b, c, d, Block[ 0], 7, $d76aa478); 
    FF (d, a, b, c, Block[ 1], 12, $e8c7b756); 
    FF (c, d, a, b, Block[ 2], 17, $242070db); 
    FF (b, c, d, a, Block[ 3], 22, $c1bdceee); 
    FF (a, b, c, d, Block[ 4], 7, $f57c0faf); 
    FF (d, a, b, c, Block[ 5], 12, $4787c62a); 
    FF (c, d, a, b, Block[ 6], 17, $a8304613); 
    FF (b, c, d, a, Block[ 7], 22, $fd469501); 
    FF (a, b, c, d, Block[ 8], 7, $698098d8); 
    FF (d, a, b, c, Block[ 9], 12, $8b44f7af); 
    FF (c, d, a, b, Block[10], 17, $ffff5bb1); 
    FF (b, c, d, a, Block[11], 22, $895cd7be); 
    FF (a, b, c, d, Block[12], 7, $6b901122); 
    FF (d, a, b, c, Block[13], 12, $fd987193); 
    FF (c, d, a, b, Block[14], 17, $a679438e); 
    FF (b, c, d, a, Block[15], 22, $49b40821); 
    GG (a, b, c, d, Block[ 1], 5, $f61e2562); 
    GG (d, a, b, c, Block[ 6], 9, $c040b340); 
    GG (c, d, a, b, Block[11], 14, $265e5a51); 
    GG (b, c, d, a, Block[ 0], 20, $e9b6c7aa); 
    GG (a, b, c, d, Block[ 5], 5, $d62f105d); 
    GG (d, a, b, c, Block[10], 9, $2441453); 
    GG (c, d, a, b, Block[15], 14, $d8a1e681); 
    GG (b, c, d, a, Block[ 4], 20, $e7d3fbc8); 
    GG (a, b, c, d, Block[ 9], 5, $21e1cde6); 
    GG (d, a, b, c, Block[14], 9, $c33707d6); 
    GG (c, d, a, b, Block[ 3], 14, $f4d50d87); 
    GG (b, c, d, a, Block[ 8], 20, $455a14ed); 
    GG (a, b, c, d, Block[13], 5, $a9e3e905); 
    GG (d, a, b, c, Block[ 2], 9, $fcefa3f8); 
    GG (c, d, a, b, Block[ 7], 14, $676f02d9); 
    GG (b, c, d, a, Block[12], 20, $8d2a4c8a); 
    HH (a, b, c, d, Block[ 5], 4, $fffa3942); 
    HH (d, a, b, c, Block[ 8], 11, $8771f681); 
    HH (c, d, a, b, Block[11], 16, $6d9d6122); 
    HH (b, c, d, a, Block[14], 23, $fde5380c); 
    HH (a, b, c, d, Block[ 1], 4, $a4beea44); 
    HH (d, a, b, c, Block[ 4], 11, $4bdecfa9); 
    HH (c, d, a, b, Block[ 7], 16, $f6bb4b60); 
    HH (b, c, d, a, Block[10], 23, $bebfbc70); 
    HH (a, b, c, d, Block[13], 4, $289b7ec6); 
    HH (d, a, b, c, Block[ 0], 11, $eaa127fa); 
    HH (c, d, a, b, Block[ 3], 16, $d4ef3085); 
    HH (b, c, d, a, Block[ 6], 23, $4881d05); 
    HH (a, b, c, d, Block[ 9], 4, $d9d4d039); 
    HH (d, a, b, c, Block[12], 11, $e6db99e5); 
    HH (c, d, a, b, Block[15], 16, $1fa27cf8); 
    HH (b, c, d, a, Block[ 2], 23, $c4ac5665); 
    II (a, b, c, d, Block[ 0], 6, $f4292244); 
    II (d, a, b, c, Block[ 7], 10, $432aff97); 
    II (c, d, a, b, Block[14], 15, $ab9423a7); 
    II (b, c, d, a, Block[ 5], 21, $fc93a039); 
    II (a, b, c, d, Block[12], 6, $655b59c3); 
    II (d, a, b, c, Block[ 3], 10, $8f0ccc92); 
    II (c, d, a, b, Block[10], 15, $ffeff47d); 
    II (b, c, d, a, Block[ 1], 21, $85845dd1); 
    II (a, b, c, d, Block[ 8], 6, $6fa87e4f); 
    II (d, a, b, c, Block[15], 10, $fe2ce6e0); 
    II (c, d, a, b, Block[ 6], 15, $a3014314); 
    II (b, c, d, a, Block[13], 21, $4e0811a1); 
    II (a, b, c, d, Block[ 4], 6, $f7537e82); 
    II (d, a, b, c, Block[11], 10, $bd3af235); 
    II (c, d, a, b, Block[ 2], 15, $2ad7d2bb); 
    II (b, c, d, a, Block[ 9], 21, $eb86d391); 
    inc(State[0], a); 
    inc(State[1], b); 
    inc(State[2], c); 
    inc(State[3], d); 
end; 

procedure MD5Init(var Context: MD5Context); 
begin 
    with Context do begin 
    State[0] := $67452301; 
    State[1] := $efcdab89; 
    State[2] := $98badcfe; 
    State[3] := $10325476; 
    Count[0] := 0; 
    Count[1] := 0; 
    ZeroMemory(@Buffer, SizeOf(MD5Buffer)); 
    end; 
end; 

procedure MD5Update(var Context: MD5Context; Input: pChar; Length: longword); 
var 
    Index: longword; 
    PartLen: longword; 
    I: longword; 
begin 
    with Context do begin 
    Index := (Count[0] shr 3) and $3f; 
    inc(Count[0], Length shl 3); 
    if Count[0] < (Length shl 3) then inc(Count[1]); 
    inc(Count[1], Length shr 29); 
    end; 
    PartLen := 64 - Index; 
    if Length >= PartLen then begin 
    CopyMemory(@Context.Buffer[Index], Input, PartLen); 
    Transform(@Context.Buffer, Context.State); 
    I := PartLen; 
    while I + 63 < Length do begin 
     Transform(@Input[I], Context.State); 
     inc(I, 64); 
    end; 
    Index := 0; 
    end else I := 0; 
    CopyMemory(@Context.Buffer[Index], @Input[I], Length - I); 
end; 

procedure MD5Final(var Context: MD5Context; var Digest: MD5Digest); 
var 
    Bits: MD5CBits; 
    Index: longword; 
    PadLen: longword; 
begin 
    Decode(@Context.Count, @Bits, 2); 
    Index := (Context.Count[0] shr 3) and $3f; 
    if Index < 56 then PadLen := 56 - Index else PadLen := 120 - Index; 
    MD5Update(Context, @PADDING, PadLen); 
    MD5Update(Context, @Bits, 8); 
    Decode(@Context.State, @Digest, 4); 
    ZeroMemory(@Context, SizeOf(MD5Context)); 
end; 

function MD5String(M: string): MD5Digest; 
var 
    Context: MD5Context; 
begin 
    MD5Init(Context); 
    MD5Update(Context, pChar(M), length(M)); 
    MD5Final(Context, Result); 
end; 



function MD5File(N: string): MD5Digest; 
var 
    FileHandle: THandle; 
    MapHandle: THandle; 
    ViewPointer: pointer; 
    Context: MD5Context; 
begin 
    MD5Init(Context); 
    FileHandle := CreateFile(pChar(N), GENERIC_READ, FILE_SHARE_READ or FILE_SHARE_WRITE, 
    nil, OPEN_EXISTING, FILE_ATTRIBUTE_NORMAL or FILE_FLAG_SEQUENTIAL_SCAN, 0); 
    if FileHandle <> INVALID_HANDLE_VALUE then try 
    MapHandle := CreateFileMapping(FileHandle, nil, PAGE_READONLY, 0, 0, nil); 
    if MapHandle <> 0 then try 
     ViewPointer := MapViewOfFile(MapHandle, FILE_MAP_READ, 0, 0, 0); 
     if ViewPointer <> nil then try 
     MD5Update(Context, ViewPointer, GetFileSize(FileHandle, nil)); 
     finally 
     UnmapViewOfFile(ViewPointer); 
     end; 
    finally 
     CloseHandle(MapHandle); 
    end; 
    finally 
    CloseHandle(FileHandle); 
    end; 
    MD5Final(Context, Result); 
end; 

function MD5Print(D: MD5Digest): string; 
var 
    I: byte; 
const 
    Digits: array[0..15] of char = 
    ('0', '1', '2', '3', '4', '5', '6', '7', '8', '9', 'A', 'B', 'C', 'D', 'E', 'F'); 
begin 
    Result := ''; 
    for I := 0 to 15 do Result := Result + Digits[(D[I] shr 4) and $0f] + Digits[D[I] and $0f]; 
end; 


function MD5Match(D1, D2: MD5Digest): boolean; 
var 
    I: byte; 
begin 
    I := 0; 
    Result := TRUE; 
    while Result and (I < 16) do begin 
    Result := D1[I] = D2[I]; 
    inc(I); 
    end; 
end; 

function RivestStr(Str: string): string; 
begin 
    Result := MD5Print(MD5String(Str)); 
end; 

function RivestFile(FileName: string): string; 
begin 
    Result := MD5Print(MD5File(FileName)); 
end; 



end.

出典

2017-01-26 Popa Ovidiu-Razvan

答えて

2

問題は、あなたのRivestStr関数は、8ビットのANSIデータを使用するように設計されたということです。 AnsiStringとPAnsiCharは、2009年以前のDelphiバージョンではデフォルトの文字列/文字タイプでした。ベルリンのような新しいDelphiのバージョンでは、デフォルトで16ビットのUnicode文字列/文字が使用されています。

ハッシングは生のバイトで行われるため、8ビット文字列と16ビットのUnicode文字列のハッシュ文字列を作成するときに、同じ印刷可能文字が含まれていても異なる結果が得られます。

実際に、あなたのRivestStr()関数とその基礎となるMD5Stringメソッドは、ベルリンのような最新のDelphiバージョンでコンパイルしたときに間違った結果を返しています。

これは、2009年以前の古いDelphiバージョンとDelphi Berlinで同じテストアプリケーション（同じコード）を作成することで確認できます。異なる結果が得られます。

ここで、問題の解決方法を教えてください。

あなたがのすべての出現交換する必要があなたのMD5ユニットで

：AnsiStringで

  • stringを。

  • charAnsiChar。

  • PCharPAnsiChar。

唯一の例外は、次のようになります。

  • CreateFile()コールをwithing NのpChar型キャストMD5File方法

  • のNパラメータ。あなたもこれらを変更することを決定した場合

することは、それが与えられたファイル名の入力としてANSI文字列を期待しているので、代わりにCreateFileA()でCreateFile()呼び出しを置き換えることを忘れないでください。

出典

2017-01-26 20:00:58 SilverWarior

5

遭遇しているのは、8ビットAnsiデータと16ビットUnicodeデータのハッシングの違いです。古いコードではAnsiデータが必要ですが、新しいコードはUnicodeデータで動作しています。ハッシュ処理は文字ではなく生のバイトで行われるため、同じデータをハッシュしていないため、異なる結果が得られます。

IndyはDelphiのデフォルトのStringタイプ（Delphi 2007以前ではAnsiString）で動作しますが、Delphi 2009以降ではUnicodeStringです。

Unicode文字列データをハッシングする場合、ハッシュする前にまずデータを特定のバイトコードに変換する必要があります。古いコードでは、Unicodeを考慮して記述されていないため、そのステップを無視します。AnsiStringが使用されているものとし、生の文字列データをそのままハッシュします。

あなたは例えば、入力されたUnicodeデータは、結果として得られたバイトをハッシュする前に変換されることを希望バイトエンコーディングを指定することができるようにTIdHashMessageDigest5.HashString...()方法は、オプションのADestEncodingのパラメータを持っている：

function MD5Hash(Value : String) : String; 
var 
    workHash : TIdHashMessageDigest5; 
begin 
    workHash := TIdHashMessageDigest5.Create; 
    try 
    // You can use whatever byte encoding you need. Indy's OSDefault 
    // encoding is the same Ansi encoding used by AnsiString on Windows 
    // (but is UTF-8 on other platforms). Note that converting Unicode 
    // data to Ansi is a potentially lossy conversion, so you should 
    // usually be using a loss-less encoding instead, such as UTF-8... 
    // 
    Result := workHash.HashStringAsHex(Value, IndyTextEncoding_OSDefault); 
    finally 
    FreeAndNil(workHash); 
    end; 
end;

を指定しない場合Indyのデフォルトバイトエンコーディングが使用され、デフォルトでUS-ASCIIに設定されています（IdGlobalユニットのグローバルGIdDefaultTextEncoding変数を使用して変更できます）。

stringがAnsiStringの場合、入力文字列は最初にAnsiからUnicodeに変換されてから、Unicodeからバイトに変換されます。したがって、HashString...()メソッドには、で使用されている実際の文字エンコーディングを、OSのデフォルトの文字エンコーディングと異なる場合に指定するために使用できるオプションのASrcEncodingパラメータもあります。

出典

2017-01-26 20:25:27

関連する問題

 関連する問題