グローバルイベントのためのフラッシュイベントリスナー

Question

私はステージが聴きたいと思うカスタムムーブイベントをディスパッチする、いくつかのムービークリップ内で開催される一連のムービークリップを持っています。イベントのリスナーをステージ（または任意のオブジェクト）に追加する方法はありますか？

たとえば、子から、またはその子のいずれか、またはその子の子から送出されたEVENT.COMPLETEをリッスンするイベントリスナーをステージに追加できますか？

Answer 1

あなたが探しているのは、イベントのバブリングです。バブリングを有効にするには、新しいイベントの3番目のプロパティをtrueに設定し、イベントをステージにディスパッチするオブジェクトから開始して、表示リストをバブルアップします。詳細については、公式ドキュメントを参照してください。

タイラー。

編集：人々は常にステージ上のイベントをキャプチャするためにバブリングイベントを使用する理由「段階から」変更はまあ

Answer 2

を「オブジェクトがイベントをディスパッチする」、これが...私は理解することは決してないだろう何かありますか？

ドックを見ると、ステージからターゲットオブジェクトにイベントが伝播し（キャプチャフェーズ）、バブルを有効にするとバブルが発生します。

そう...ちょうどキャプチャを使用します。

Main.as 

package { 
    import flash.display.Sprite; 

    public class Main extends Sprite 
    { 
     public function Main() 
     { 
      var c:Circle = new Circle(); 
      var r:Rect = new Rect(); 
      c.addChild(r); 
      addChild(c); 
      addEventListener(CustomEvent.CUSTOM, customEventHandler, true);//don't forget third parameter to use capture 
     } 

     private function customEventHandler(e:CustomEvent):void 
     { 
      trace(e.eventPhase == EventPhase.CAPTURING_PHASE);//shows true 
     } 
    } 
} 

Circle.as 

package 
{ 
    import flash.display.Sprite; 
    import flash.events.Event; 
    import flash.events.MouseEvent; 

    public class Circle extends Sprite 
    { 
     public function Circle() 
     { 
      super(); 
      init(); 
     } 

     private function init():void 
     { 
      with(graphics) 
      { 
       beginFill(0xFF0000); 
       drawCircle(25, 25, 50); 
       endFill() 
      } 

     } 
    } 
} 

Rect.as 

package 
{ 
    import flash.display.Sprite; 
    import flash.events.MouseEvent; 

    public class Rect extends Sprite 
    { 
     public function Rect() 
     { 
      super(); 
      init(); 
     } 

     private function init():void 
     { 
      with(graphics) 
      { 
       beginFill(0x000000); 
       drawRect(0, 0, 25, 25); 
       endFill(); 
      } 

      addEventListener(MouseEvent.CLICK, mouseClickHandler); 
     } 

     private function mouseClickHandler(e:MouseEvent):void 
     { 
      dispatchEvent(new CustomEvent(CustomEvent.CUSTOM)); 
     } 


    } 
} 

CustomEvent.as

package 
{ 
    import flash.events.Event; 

    public class CustomEvent extends Event 
    { 
     public static const CUSTOM:String = "custom"; 

     public function CustomEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false) 
     { 
      super(type, bubbles, cancelable); 
     } 

    } 
}