VBA Excel：値によって1つの線図で色分けされます

Question

私は、値そのものや出所などに応じて、Excelの図の同じ折れ線グラフに3種類の色を表示する方法を探していますどのシートfe）。今まで

、私は次のコードを持っている：

Sub ChangeColor() 
Dim i As Integer 
Dim IntRow As Integer 
Dim r As Range 

ActiveSheet.ChartObjects("Cash").Activate 
ActiveChart.SeriesCollection(1).Select 

IntRow = ActiveChart.ChartObjects("Cash").Count 

For i = 2 To IntRow 
    Set r = Cells(2, i) 
    If r.Value < 3000 Then 
     Selection.Border.ColorIndex = 5 
    Else 
     Selection.Border.ColorIndex = 9 
    End If 
Next 
End Sub 

しかし、声明を考慮して、私は最初のColorIndexを変更するたびに行全体の色のみが変更されていない場合。根底にあるテーブルの値に応じて、行の一部をどのように色付けするかはわかりません。

さらに、IntraowをActiveChart.ChartObjects("Cash").Countと定義すると、配列の長さを取得できません。この問題は、手作業でカウントしてIntRowを整数として宣言することで解決できますが、上記のバージョンはより良いように見えます（もちろん可能な場合）。

ご協力いただきありがとうございます。ありがとうございました。

アレクサンドラ

Answer 1

あなたはグラフ系列から直接値を読み取ることができます。

Sub ChangeColor() 
    Dim cht As Chart, p As Point, s As Series 
    Dim i As Integer 
    Dim numPts As Long 

    'access the chart directly - no select/activate required 
    Set cht = ActiveSheet.ChartObjects("Cash").Chart 

    'reference the first series 
    Set s = cht.SeriesCollection(1) 

    'how many points in the first series? 
    numPts = s.Points.Count 

    'loop over the series points 
    For i = 1 To numPts 

     Set p = cht.SeriesCollection(1).Points(i) 

     p.Border.ColorIndex = IIf(s.Values(i) < 3000, 5, 9) 

    Next 
End Sub