DelphiでGetHashCodeのdouble型を整数に変換する

Question

Delphi 2009では、TObjectにGetHashCode関数が追加されました。 GetHashCodeは、TDictionaryのハッシュに使用されるIntegerを返します。

オブジェクトがTDictionaryでうまく動作するようにするには、GetHashCodeを適切にオーバーライドして、一般に異なるオブジェクトが異なる整数ハッシュコードを返すようにする必要があります。

しかし、ダブルフィールドを含むオブジェクトではどうしますか？どのようにGetHashCodeの整数にこれらのdouble値を変換しますか？

Javaで通常行われる方法は、Double.doubleToLongBitsやFloat.floatToIntBitsなどのメソッドを使用することです。後者には、次のようなドキュメントがあります。「IEEE 754浮動小数点「単一形式」ビットレイアウトに従って、指定された浮動小数点値の表現を返します。これは、浮動小数点値の異なるビットに対する異なるマスクを用いたいくつかのビット演算を含む。

Delphiでこれを行う関数はありますか？

Answer 1

私はGamecatコードに比べて次のような改善をお勧めしたい：

type 
    TVarRec = record 
    case Integer of 
     0: (FInt1, FInt2 : Integer;) 
     1: (FDouble : Double;) 
    end; 

function Convert(const ADouble: Double): Integer; 
var 
    arec : TVarRec; 
begin 
    arec.FDouble := ADouble; 
    Result := arec.FInt1 xor arec.FInt2; 
end; 

これは、アカウントに、すべてのビットを取ります

（コメントはコードでうまく機能しません）

Answer 2

あなたは整数にダブルをマッピングする場合は、バリアントレコードを使用することができます。

type 
    TVarRec = record 
    case Integer of 
     0: (FInt : Integer;) 
     1: (FDouble : Double;) 
    end; 


function Convert(const ADouble: Double): Integer; 
var 
    arec : TVarRec; 
begin 
    arec.FDouble := ADouble; 
    Result := arec.FInt; 
end; 

がこの値の解釈せずにビット単位のコピーを行うことに注意してください。

別（ダーティトリックの種類、絶対的な変数を使用している：

function Convert(const ADouble: Double): Integer; 
var 
    tempDouble : Double; 
    tempInt : Integer absolute tempDouble; // tempInt is at the same memory position as tempDouble. 
begin 
    tempDouble := ADouble; 
    Result := tempInt; 
end; 

Answer 3

GetHashCodeのデフォルト値は、オブジェクトごとに一意であることが保証されている数値、つまりオブジェクトのメモリアドレスを返すので、このようなことをする必要はありません。さらに、オブジェクトに含まれるデータを変更すると、デフォルトのハッシュ値は変更されません。

値3.5のDoubleを含むオブジェクトをハッシュして辞書に入れ、ハッシュコード12345678を取得したとしましょうDoubleフィールドは変更され、現在は5.21という値が得られています。次にハッシュ値を計算しようとすると、ハッシュコードが23456789になり、検索が失敗します。

これが起こらないことを保証できない限り、メモリアドレスを使用しない本当の理由がある場合は、GetHashCodeをそのまま残すことをお勧めします。 （それが壊れていない場合は、それを修正しないでください。）

Answer 4

私は、Javaのことは、このようにDelphiで実装することができますね。

type 
    TVarRec = record 
    case Integer of 
     0: (FInt1: Integer;) 
     1: (FSingle: Single;) 
    end; 

function GetHashCode(Value: Double): Integer; 
var 
    arec: TVarRec; 
begin 
    arec.FSingle := Value; 
    Result := arec.FInt1; 
end; 

の背後にある考え方は、ダブルの精度を削減することですInteger（Sizeof（Single）= Sizeof（Integer））のバイナリサイズと一致する値。あなたの値が衝突なしで単精度で表現できる場合、これは良いハッシュ値を与えます。

編集：D2009でタイプキャストがコンパイルされないため、私はバリアントレコードソリューションを採用しました。

Answer 5

xorが悪いので、ダブルデータでCRC32を使用してください。

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    SysUtils; 

type 
    TVarRec = record 
    case Integer of 
     0: (FInt1, FInt2 : Integer;); 
     1: (FDouble : Double;); 
    end; 

function Convert(const ADouble: Double): Integer; 
var 
    arec : TVarRec; 
begin 
    arec.FDouble := ADouble; 
    Result := arec.FInt1 xor arec.FInt2; 
end; 

var 
    FDoubleVar1, FDoubleVar2: TVarRec; 
    HashCode1, HashCode2: Integer; 
begin 
    // Make a Double 
    FDoubleVar1.FInt1 := $DEADC0DE; 
    FDoubleVar1.FInt2 := $0C0DEF00; 

    // Make another Double 
    FDoubleVar2.FInt1 := $0C0DEF00; 
    FDoubleVar2.FInt2 := $DEADC0DE; 

    WriteLn('1rst Double : ', FDoubleVar1.FDouble); 
    WriteLn('2nd Double : ', FDoubleVar2.FDouble); 

    HashCode1 := Convert(FDoubleVar1.FDouble); 
    HashCode2 := Convert(FDoubleVar2.FDouble); 

    WriteLn('1rst HashCode : ', HashCode1); 
    WriteLn('2nd HashCode : ', HashCode2); 

    if HashCode1 = HashCode2 then 
    begin 
    WriteLn('Warning: Same HashCode!'); 
    end; 
    ReadLn; 
end.