バブルチャートにシリーズ名の付いたデータラベルを追加する

Question

データラベルをバブルチャートに追加するマクロがあります。このコードはY軸の値を提供するのに最適ですが、これを代わりにSeriesNameを表示するように変更したいと思います。

Sub AddDataLabels() 

Dim bubbleChart As ChartObject 
Dim mySrs As Series 
Dim myPts As Points 

With ActiveSheet 
    For Each bubbleChart In .ChartObjects 
     For Each mySrs In bubbleChart.Chart.SeriesCollection 
      Set myPts = mySrs.Points 
      myPts(myPts.Count).ApplyDataLabels Type:=xlShowValue 
     Next 
    Next 
End With 

End Sub 

私は中に、

myPts(myPts.Count).ApplyDataLabels Type:=xlShowValue 

を変更してみてください：

myPts(myPts.Count).ApplyDataLabels Type:=xlShowSeriesName 

しかし、それは私に '無効なプロシージャ呼び出しまたは引数' を提供します。

私はSERIESNAMEの代わりに、Y軸の値を表示するコードを変更する方法上の任意のアドバイスはありますか？

Answer 1

あなたのコード内の以下の私のコードでWithステートメントを追加し、必要に応じて内部のパラメータを調整します。

下のコードでは、DaralabelsにはSeriesNameが表示されますが、カテゴリや値は表示されません。

Sub AddDataLabels() 

Dim bubbleChart As ChartObject 
Dim mySrs As Series 
Dim myPts As Points 

With ActiveSheet 
    For Each bubbleChart In .ChartObjects 
     For Each mySrs In bubbleChart.Chart.SeriesCollection 
      Set myPts = mySrs.Points 

      myPts(myPts.Count).ApplyDataLabels 

      With myPts(myPts.Count).DataLabel 
       .ShowSeriesName = True 
       .ShowCategoryName = False 
       .ShowValue = False 
       ' optional parameters 
       .Orientation = 0 
       .Font.Size = 10 
       .Font.Bold = True 
      End With 

     Next 
    Next 
End With 

End Sub 

Answer 2

これは機能しますか？

bubbleChart.ApplyDataLabels xlDataLabelsShowLabel