IsEmptyが機能しなくなるまで、アイデアはありますか？

Question

私は期間を得るために日付を含む2つのセルの間で簡単な減算をしています。 Data_pワークシートのRange（ "4"）内のすべてのクライアントは、それぞれの列にすべての受注日を持ちます。したがって、減算は2番目の日付と1番目の日付の間で行われ、結果はData_p_mgntに貼り付けられます。この関数は、クライアントごとに日付がなくなるまで実行する必要があります。

私は以下のコードを持っていますが、Data_pで空のセルが見つかった場合に停止しない理由はわかりません。どんな洞察にも感謝します。

Sub Prueba_Data_p_mgnt() 

Sheets("Data_p_mgnt").Select 
Range("B5").Select 'Starts in cell B5 

Do Until IsEmpty(Worksheets("Data_p").Range("B5")) 'Checks if cells in Data_p are Empty or Blank 

ActiveCell.FormulaR1C1 = "=Data_p!R[1]C-Data_p!RC" 'Makes the subtraction between cells 
ActiveCell.Offset(1, 0).Range("A1").Select 'Moves down for paste the next period 

Loop 'Loop until there's an Empty cell in Data_p 

'Then should move to next client to the right and repeat until there are no more clients in row 4 

End Sub 

Answer 1

私は、これはあなたがやろうとしているものであると信じて：

Sub Prueba_Data_p_mgnt() 
    Dim wsMgnt As Worksheet 
    Dim wsData As Worksheet 
    Dim rowNo As Long 
    Dim colNo As Long 
    Set wsMgnt = Worksheets("Data_p_mgnt") 
    Set wsData = Worksheets("Data_p") 

    colNo = 2 
    Do Until IsEmpty(wsData.Cells(4, colNo)) 'Checks if cells in Data_p are Empty or Blank 

     rowNo = 5 
     Do Until IsEmpty(wsData.Cells(rowNo, colNo)) 'Checks if cells in Data_p are Empty or Blank 
     'Alternatively, to avoid subtracting the last non-blank cell from a blank cell 
     'Do Until IsEmpty(wsData.Cells(rowNo + 1, colNo)) 'Checks if cells in Data_p are Empty or Blank 

      wsMgnt.Cells(rowNo, colNo).FormulaR1C1 = "=Data_p!R[1]C-Data_p!RC" 'Makes the subtraction between cells 
      'Alternatively, if you would rather have values than formulae 
      'wsMgnt.Cells(rowNo, colNo).Value = wsData.Cells(rowNo + 1, colNo).Value - wsData.Cells(rowNo, colNo).Value 

      rowNo = rowNo + 1 'Moves down for paste the next period 
     Loop 'Loop until there's an Empty cell in Data_p 

     colNo = colNo + 1 'Then should move to next client to the right and repeat until there are no more clients in row 4 
    Loop 

End Sub 

Answer 2

これは、私は願って、トリックを行う必要があります。

Sub Prueba_Data_p_mgnt() 
Dim dataWS As Worksheet 
Dim rng As Range 
Set dataWS = Sheets("Data_p_mgnt") 

Set rng = dataWS.Range("B5") ' what's this? You never use data_p_mgnt cell B5? 

For i = 5 To 100 ' Change 100 to whatever you need 
    If Not IsEmpty(Worksheets("Data_p").Range("b" & i)) Then 'Checks if cells in Data_p are Empty or Blank 
     Worksheets("Data_p").Range("b" & i).FormulaR1C1 = "=Data_p!R[1]C-Data_p!RC" 'Makes the subtraction between cells 
    End If 'Loop until there's an Empty cell in Data_p 
Next i 
End Sub 

しかし、あなたのコードを見て、私はあなたがData_p_mgntシート上B5を行う上で計画しているかわかりません。