delphi 7 for 64 bit server 2008、問題

Question

誰もがWindows Server 2008 64ビット版で独自のWindowsサービス（32ビットアプリケーション）プロセスにデルファイを添付しようとしましたか？

これを実行しようとすると、エラーが発生します。 プロセスを作成できません。パラメータが正しくありません。

あなたの誰かがこれを行う方法を知っているなら、その助けは本当に感謝します。

ありがとうございます！

Answer 1

Delphiサービスをデバッグすることはできますが、機能させるにはジャンプする必要があります。私は心配することはありませんし、私のサービスがサービスとして、または標準のアプリケーションとして実行できることを単に保証します。私がデバッグしたいとき、私は標準的なアプリケーションとして実行し、すべての頭痛を回避します。

私はこの答えの目的ですべてのコードを1つのファイルにハックしましたが、少し異なって構造化したいと思います。

program MyService; 

uses 
    SysUtils, Classes, Windows, Forms, SvcMgr; 

type 
    TMyService = class(TService) 
    private 
    procedure ServiceStart(Sender: TService; var Started: Boolean); 
    procedure ServiceStop(Sender: TService; var Stopped: Boolean); 
    procedure ServicePause(Sender: TService; var Paused: Boolean); 
    procedure ServiceExecute(Sender: TService); 
    procedure ServiceContinue(Sender: TService; var Continued: Boolean); 
    protected 
    FDescription: string; 
    FEventLogSourceName: string; 
    procedure Initialise; virtual; abstract; 
    class function CreateRunner: TObject; virtual; abstract; 
    public 
    constructor Create(AOwner: TComponent); override; 
    function GetServiceController: TServiceController; override; 
    end; 
    TMyServiceClass = class of TMyService; 

{ TMyService } 

constructor TMyService.Create(AOwner: TComponent); 
begin 
    inherited; 
    Initialise; 
    OnStart := ServiceStart; 
    OnStop := ServiceStop; 
    OnPause := ServicePause; 
    OnExecute := ServiceExecute; 
    OnContinue := ServiceContinue; 
end; 

procedure TMyService.ServiceStart(Sender: TService; var Started: Boolean); 
begin 
    Started := True; 
end; 

procedure TMyService.ServiceStop(Sender: TService; var Stopped: Boolean); 
begin 
    Stopped := True; 
end; 

procedure TMyService.ServiceContinue(Sender: TService; var Continued: Boolean); 
begin 
    ServiceStart(Sender, Continued); 
end; 

procedure TMyService.ServicePause(Sender: TService; var Paused: Boolean); 
begin 
    ServiceStop(Sender, Paused); 
end; 

procedure TMyService.ServiceExecute(Sender: TService); 
var 
    Runner: TObject; 
begin 
    Runner := CreateRunner; 
    Try 
    while not Terminated do begin 
     ServiceThread.ProcessRequests(True); 
    end; 
    Finally 
    FreeAndNil(Runner); 
    End; 
end; 

var 
    Service: TMyService; 

procedure ServiceController(CtrlCode: DWORD); stdcall; 
begin 
    Service.Controller(CtrlCode); 
end; 

function TMyService.GetServiceController: TServiceController; 
begin 
    Result := ServiceController; 
end; 

procedure RunAsService(ServiceClass: TMyServiceClass; var Service); 
var 
    Application: TServiceApplication; 
begin 
    Application := SvcMgr.Application; 
    Application.Initialize; 
    Application.CreateForm(ServiceClass, Service); 
    Application.Run; 
end; 

procedure RunAsStandardExecutable(ServiceClass: TMyServiceClass); 
var 
    Application: TApplication; 
    Runner: TObject; 
begin 
    Application := Forms.Application; 
    Application.Initialize; 
    Runner := ServiceClass.CreateRunner; 
    Try 
    while True do begin 
     Try 
     Application.HandleMessage; 
     Except 
     Application.HandleException(Application); 
     End; 
    end; 
    Finally 
    FreeAndNil(Runner); 
    End; 
end; 

procedure ServiceMain(ServiceClass: TMyServiceClass); 
begin 
    if FindCmdLineSwitch('RunAsApp', ['-', '/'], True) then begin 
    RunAsStandardExecutable(ServiceClass); 
    end else begin 
    RunAsService(ServiceClass, Service); 
    end; 
end; 

begin 
    ServiceMain(TMyService); 
end. 

あなたはTMyServiceから継承された新しいクラスを作成し、InitialiseとCreateRunnerを実装する必要があり、これを使用するには。 CreateRunnerが鍵です。私のサービスでは、オブジェクトが作成され、クライアントが通信する準備が整った待機ソケットが開きます。

標準のアプリケーションコードはかなり基本的です。終了するメカニズムもありません。ループはwhile Trueループ内で実行されます。それは私のデバッグニーズには関係ありません。

Answer 2

管理者としてIDEを実行しようとしましたか？

私は既にWin64でこのようなプロセスをアタッチしていますが、覚えている限り、私は管理者権限でIDEを実行しなければなりませんでした。