ファイルを管理するためのバッチファイルを少し作成する

Question

まず、英語がうまくない場合は申し訳ありませんが、私はスペイン出身です。

私はINSTANCEというフォルダの中にたくさんのフォルダ（数十個）に広がったたくさんのファイル（数千）を持っています。ファイルタイプは2つしかありません（* .new、* .old）。すべてのフォルダに2つのフォルダがあります。私はそれぞれの* .newファイルを100個ごとに新しいフォルダの中に移動する必要があります。 * .oldファイルが存在する場合は、それらをすべて別のフォルダに移動します。私は手でそれをやってみましたが、数時間後にはこれが大きな仕事であることを認識していますので、バッチファイルですべてのフォルダを一度に実行するか、すべてのフォルダINSTANCEフォルダー内にあります。

混乱するように聞こえるかもしれませんが、私は最初の例を示し、それがどのようにしなければならないかの2番目の例を示します（100sの代わりに3sのグループを示します）。

前：

D:\[2016]\[01 JANUARY]\INSTANCE 
│ 
├───aaa 
│  01.new 
│  02.new 
│  03.new 
│  04.new 
│  05.new 
│  13.old 
│  14.old 
│ 
├───bbb 
│  01.new 
│  02.new 
│  03.new 
│  04.new 
│  05.new 
│  06.new 
│  07.new 
│  08.new 
│  13.old 
│  14.old 
│  15.old 
│ 
├───ccc 
│  01.new 
│  02.new 
│  03.new 
│  04.new 
│  05.new 
│ 
└───ddd 
     01.new 
     02.new 
     03.new 
     04.new 
     05.new 
     06.new 
     07.new 
     08.new 
     09.new 
     11.old 

後：

D:\[2016]\[01 JANUARY]\INSTANCE 
│ 
├───aaa 
│ ├───01 
│ │  01.new 
│ │  02.new 
│ │  03.new 
│ │ 
│ ├───02 
│ │  04.new 
│ │  05.new 
│ │ 
│ └───zz 
│   13.old 
│   14.old 
│ 
├───bbb 
│ ├───01 
│ │  01.new 
│ │  02.new 
│ │  03.new 
│ │ 
│ ├───02 
│ │  04.new 
│ │  05.new 
│ │  06.new 
│ │ 
│ ├───03 
│ │  07.new 
│ │  08.new 
│ │ 
│ └───zz 
│   13.old 
│   14.old 
│   15.old 
│ 
├───ccc 
│ ├───01 
│ │  01.new 
│ │  02.new 
│ │  03.new 
│ │ 
│ └───02 
│   04.new 
│   05.new 
│ 
└───ddd 
    ├───01 
    │  01.new 
    │  02.new 
    │  03.new 
    │ 
    ├───02 
    │  04.new 
    │  05.new 
    │  06.new 
    │ 
    ├───03 
    │  07.new 
    │  08.new 
    │  09.new 
    │ 
    └───zz 
      11.old 

要約：

Look inside INSTANCE 

    for every folder inside 

    if any *.old file exists create a folder called ZZ and move there all of them 

    Then 

    create folder 01 and move 100 of the *.new files 
    create folder 02 and move the next 100 
    create folder 03 and move the next 100 
    ... 

Until all the files have been moved 

検索する前に、どのように私はプログラマではないので、それが可能かどうかを知りたいと思っています。それは、私にとっては、一度だけのことなので、学習曲線です。私はいくつかのコマンド（MD、IF EXIST、MOVEなど）のいくつかを助けることができるいくつかのコマンドがあると読んでいますが、すべてを単一のバッチファイルで行うことはできません。

ありがとうございます。

Answer 1

@ECHO OFF 
SETLOCAL 
SET "sourcedir=U:\sourcedir\t w o\instance" 
SET /a filesperdir=3 
PUSHD "%sourcedir%" 

REM For each directory found in "sourcedir" 
FOR /f "delims=" %%a IN (
'dir /b /ad "*" ' 
) DO (
SET "dirname=%%a" 
REM initialise subdirectory counter and file counter 
SET /a subcount=0 
SET /a filecount=filesperdir 
REM scan for files "*.new" 
FOR /f "delims=" %%c IN (
    'dir /b /a-d ".\%%a\*.new" 2^>nul' 
) DO (
    REM name of file and move 
    SET "filename=%%c" 
    CALL :movenew 
) 
REM scan for files "*.old" 
FOR /f "delims=" %%c IN (
    'dir /b /a-d ".\%%a\*.old" 2^>nul' 
) DO (
    rem move to "zz" 
    MD ".\%%a\zz" >NUL 2>NUL 
    ECHO(MOVE ".\%%a\%%c" ".\%%a\zz\" 
) 
) 

popd 

GOTO :EOF 

:movenew 
REM one more file... 
SET /a filecount +=1 
REM filled this subdirectory? 
if %filecount% gtr %filesperdir% SET /a subcount+=1&SET /a filecount=1 
SET /a subnum=1000+subcount 
REM try to make subdirectory 
MD ".\%dirname%\%subnum:~-2%" >nul 2>nul 
ECHO(MOVE ".\%dirname%\%filename%" ".\%dirname%\%subnum:~-2%\" 
GOTO :eof 

sourcedirの設定を状況に合わせて変更する必要があります。

必要なMOVEコマンドは、テストのために単なるECHOです。 コマンドが正しいことを確認したら、をECHO(MOVEからMOVEに変更して、実際にファイルを移動します。 >nulを追加してレポートメッセージを抑制する（例：1 file moved）

私はジョブの仕組みについてインラインでコメントしました。あなたはこのトリック（REMの代わりに::）がACODEブロック（文の括弧のシリーズ）内で動作していないため（多くの場合、迅速・ツー・タイプの代わりに使用）

ラフアウトラインをremない::を使用する必要があることに注意してください：reacサブディレクトリが見つかった場合は、サブディレクトリ数を0に、filecountをmaxに設定します。最初に.newファイルのサブディレクトリを処理し、次に.oldを処理します。 oldファイルの場合、処理は単純です。それらをサブディレクトリzzに移動するだけです。 newファイルの場合は、サブルーチンmovenewを実行します。

:movenewは、count-of-files-movedに1を加算し、結果が許容数より大きい場合は、サブディレクトリ数をインクリメントしてファイル数をリセットします。subcountから1000がsubnumは常に4桁であることを確実にする追加 -

次いで、サブディレクトリ名（文字列の最後の2文字）を算出するsubnumを使用します。 ディレクトリを作成し、ファイルを移動します。

ディレクトリがすでに存在する場合、mdはエラーメッセージを作成します。 2>nulは、このエラーメッセージを抑制します。 dirコマンド内の2^>nulは、目的のファイルタイプを含まないディレクトリに対しても同様の目的を果たします。キャレット^は、>が実行中のコマンドの一部であり、forではないことをプロセッサに伝えます。

Answer 2

@echo off 
setlocal EnableDelayedExpansion 

rem Look inside INSTANCE 
cd /D "D:\[2016]\[01 JANUARY]\INSTANCE" 

rem for every folder... 
for /D %%f in (*) do (
    rem ... inside 
    cd "%%f" 

    rem if any *.old file exists... 
    if exist *.old (
     rem ... create a folder called ZZ... 
     md ZZ 
     rem ... and move there all of them 
     move *.old ZZ 
    ) 

    rem Then, create folders with two-digits and move 100 *.new files to each one 
    set /A twoDigits=100, files=-1 
    for %%a in (*.new) do (
     set /A files+=1, filesMOD100=files%%100 
     rem Every 100 files, when the remainder of files/100 is zero... 
     if !filesMOD100! equ 0 (
     rem ... create a new two-digits folder 
     set /A twoDigits+=1 
     md !twoDigits:~-2! 
    ) 
     move "%%a" !twoDigits:~-2! 
    ) 

    rem Go back to original folder -INSTANCE- 
    cd .. 

)