Excel 2010 VBAコードが実行されていません

Question

私は現在Excel 2010を使用していますが、アプリケーション用にVBAに組み込んだコードを実行しようとしています（alt + F11を押した後）。私が作業したいプロジェクトをダブルクリックした後に表示されるメモ帳にコードを入力しました。 Excel Macro Enabled Workbook（* .xlsm）としてすべて保存しました。

S、T、およびUの列が基準を満たしている場合、列Dの背景を緑色または赤色に色付けしようとしています。列の値がすべて0の場合、セルDは緑色になります。そうでない場合は、赤色に着色してください。

Sub GreenOrRed() 
    Dim i As Integer 
    For i = 2 To i = 27293 
    If (Cells(i, "S").Value = 0 And Cells(i, "T").Value = 0 And Cells(i, "U").Value = 0) Then 
     Cells(i, "D").Interior.ColorIndex = 10 
    Else 
     Cells(i, "D").Interior.ColorIndex = 9 
    End If 
    Next i 
End Sub 

コードは実行され、エラーは発生しませんが、何も行われません。私は間違って何をしていますか？

Answer 1

Forループでcounterを間違って使用しています。これはこのようなはずです...

For i = 2 To 27293 

Answer 2

変更されたFor conditionです。 これを試してください： -

Sub GreenOrRed() 
    Dim i As Integer 
    For i = 2 To 27293 
    If (Cells(i, "S").Value = 0 And Cells(i, "T").Value = 0 And Cells(i, "U").Value = 0) Then 
     Cells(i, "D").Interior.ColorIndex = 10 
    Else 
     Cells(i, "D").Interior.ColorIndex = 9 
    End If 
    Next i 
End Sub 

Answer 3

A、わずかに異なるアプローチを：

Sub GreenOrRed() 
    Dim r As Range, rr As Range 
    Set rr = Range("D1:D27293") 

    For Each r In rr 
     If r.Offset(0, 15).Value = 0 And r.Offset(0, 16).Value = 0 And r.Offset(0, 17).Value = 0 Then 
      r.Interior.ColorIndex = 10 
     Else 
      r.Interior.ColorIndex = 9 
     End If 
    Next r 
End Sub 

Answer 4

あなたが1つ（または2）条件付き書式ルールを設定することを検討することがあります。

私は個々のSUM関数を使用して、テキストがゼロの数値を返すようにしました。

代替オートフィルタ方式。

Sub GreenOrRedFiltered() 
    With ActiveSheet 
     If .AutoFilterMode Then .AutoFilterMode = False 
     With .Range(.Cells(1, "D"), .Cells(.Rows.Count, "D").End(xlUp)).Resize(, 18) 
      .Resize(.Rows.Count - 1, .Columns.Count).Offset(1, 0).Columns(1).Interior.ColorIndex = 9 
      .AutoFilter Field:=16, Criteria1:=0, Operator:=xlOr, Criteria2:=vbNullString 
      .AutoFilter Field:=17, Criteria1:=0, Operator:=xlOr, Criteria2:=vbNullString 
      .AutoFilter Field:=18, Criteria1:=0, Operator:=xlOr, Criteria2:=vbNullString 
      With .Resize(.Rows.Count - 1, .Columns.Count).Offset(1, 0) 
       If CBool(Application.Subtotal(103, .Cells)) Then 
        .Columns(1).SpecialCells(xlCellTypeVisible).Interior.ColorIndex = 10 
       End If 
      End With 
     End With 
     If .AutoFilterMode Then .AutoFilterMode = False 
    End With 
End Sub