ループ内のコンテキストをDelphiのTTask.IFutureに渡すにはどうすればよいですか？

Question

私は配列の中で実行する一連のタスクを持っています。私は配列をループし、それぞれのタスクを起動したい。

次の例は、問題を示すために自明な（四角形の計算）例です。

program FutureSquares; 

{$APPTYPE CONSOLE} 

{$R *.res} 

uses 
    System.SysUtils, 
    System.Threading, 
    System.Classes; 
const 
    nums: array[0..9] of Integer = (1,2,3,4,5,6,7,8,9,10); 
var 
    i, contextIndex: Integer; 
    f: array[0..9] of ITask; 
    answer, futureAnswer: Integer; 
    matchDisplay: string; 
    futureFunc: TFunc<Integer>; 
begin 

    try 
    for i := Low(f) to High(f) do 
    begin 
     contextIndex := i; 

     futureFunc := function: Integer 
     begin 
      Sleep(Random(1000)); 
      Result := nums[contextIndex]*nums[contextIndex]; // trying because a reference to it is captured. How to capture the actual value? 
     end; 

     f[i] := TTask.Future<Integer>(futureFunc); 
     f[i].Start; 
    end; 

    //verify results in sequential manner 
    for i := Low(f) to High(f) do 
    begin 
     answer := nums[i]*nums[i]; 
     futureAnswer := IFuture<Integer>(f[i]).Value; 
     if futureAnswer = answer then 
     matchDisplay := 'match' 
     else 
     matchDisplay := 'MISMATCH'; 
     writeln(Format('%d * %d = %d. Future<Integer> = %d - %s', [nums[i],nums[i],answer, futureAnswer, matchDisplay])); 
    end; 

    readln; 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
end. 

次のようにプログラムからの出力は次のようになります。

1 * 1 = 1. Future<Integer> = 16 - MISMATCH 
2 * 2 = 4. Future<Integer> = 100 - MISMATCH 
3 * 3 = 9. Future<Integer> = 100 - MISMATCH 
4 * 4 = 16. Future<Integer> = 100 - MISMATCH 
5 * 5 = 25. Future<Integer> = 100 - MISMATCH 
6 * 6 = 36. Future<Integer> = 100 - MISMATCH 
7 * 7 = 49. Future<Integer> = 100 - MISMATCH 
8 * 8 = 64. Future<Integer> = 100 - MISMATCH 
9 * 9 = 81. Future<Integer> = 100 - MISMATCH 
10 * 10 = 100. Future<Integer> = 100 - match 

どのように私は私の目標を達成することができますか？

私は、TTask.Futureはそれに便利なコンテキストを渡すことができないことに注意してください。

Answer 1

匿名メソッドでは変数ではなく値を取得する必要があります。これを行う最も簡単な方法は、匿名メソッドをスタンドアロン関数に置き、キャプチャしたいインデックスを渡すことです。これにより、変数の代わりに値が取得されます。

function CaptureFuture(const aTheIndex: Integer): TFunc<Integer>; 
begin 
    Result := function: Integer 
    begin 
     Sleep(Random(1000)); 
     Result := nums[aTheIndex]*nums[aTheIndex]; // trying because a reference to it is captured. How to capture the actual value? 
    end; 
end; 

そして、あなたはfutureFuncの割り当てを行うときに、あなたのコードは次のようになります。

for i := Low(f) to High(f) do 
begin 
    futureFunc := CaptureFuture(i); 

    f[i] := TTask.Future<Integer>(futureFunc); 
    f[i].Start; 
end; 

これはあなたの望ましい結果が得られます：

1 * 1 = 1. Future<Integer> = 1 - match 
2 * 2 = 4. Future<Integer> = 4 - match 
3 * 3 = 9. Future<Integer> = 9 - match 
4 * 4 = 16. Future<Integer> = 16 - match 
5 * 5 = 25. Future<Integer> = 25 - match 
6 * 6 = 36. Future<Integer> = 36 - match 
7 * 7 = 49. Future<Integer> = 49 - match 
8 * 8 = 64. Future<Integer> = 64 - match 
9 * 9 = 81. Future<Integer> = 81 - match 
10 * 10 = 100. Future<Integer> = 100 - match 

は、この質問を参照してください。変数と値のキャプチャの詳細については、 Anonymous methods - variable capture versus value capture