VB6でコードを使ってオブジェクトを作成する

Question

私はVisual Basic 6でプログラムを持っているので、コードで自分のプログラムにボタンを作成する必要があります。

私はこのコードを書く：

private sub Pulso_click() 
    dim boton as CommandButton 
    set boton = new CommandButton 
    boton.width = 100 
    boton.height = 30 
    boton.caption = "MiBoton" 

End Sub 

をしかし、実行しないでください。私は "El uso de la palabra clave New no es valido"、 英語で "キーワードNew use invalid"を持っています。

これはVisual Basic 6で実行されます

問題はどこですか？ありがとう

Answer 1

あなたのコードはVB6 IDEに由来していません。私はあなたがIDEを持っていると思いますよね？その場合：

コードでCommandButtonを作成することはできません。実行時に必要な場合は、コントロールフィールドが必要です。コントロールフィールドを作成するには、フォームにCommandButtonコントロールを配置します。インデックス0を指定します。VisibleプロパティをFalseに設定します。

コードにはピクセルが含まれているようです。フォームのScaleModeプロパティを3ピクセルに設定します。

このテンプレートからさらにインスタンスを作成できます。

Private Sub Form_Load() 
    Load Command1(1) 
    With Command1(1) 
     .Top = 10 
     .Left = 10 
     .Width = 100 
     .Height = 30 
     .Caption = "MiBoton 1" 
     .Visible = True 
     .ZOrder 
    End With 

    Load Command1(2) 
    With Command1(2) 
     .Top = 10 
     .Left = 120 
     .Width = 100 
     .Height = 30 
     .Caption = "MiBoton 2" 
     .Visible = True 
     .ZOrder 
    End With 
End Sub 

Answer 2

このコードは、私のために私のために何の問題もなく

Option Explicit 
' 
Dim WithEvents Cmd1 As CommandButton 
' 
Private Sub Form_Load() 
    Set Cmd1 = Controls.Add("vb.commandbutton", "Cmd1") 
    Cmd1.Width = 2000 
    Cmd1.Top = Me.Height/2 - Cmd1.Height/2 - 100 
    Cmd1.Left = Me.Width/2 - Cmd1.Width/2 - 100 
    Cmd1.Caption = "Dynamic Button" 
    Cmd1.Visible = True 
End Sub 
' 
Private Sub Cmd1_click() 
    MsgBox "I have been Created Dynamically at Run-time", _ 
    , "Dynamic Controls" 
End Sub 
' 

ワークス作品、私はあなたにもインデックスを使用することができ、このコードはあなたのために働く願って1つのコマンドボタンとセットを作成しますフォームのロード時に0にしてから、表示するときはいつでもインデックスを表示します。

Load Command1(1) 
Command1(1).Caption = "command2" 
Command1(1).Left = Command1(0).Left + Command1(0).Width 
Command1(1).Top = Command1(0).Top 
Command1(1).Visible = True 

あなたはポイントを得る、幸運、私は多くのコントロールをたくさん持っているときにインデックスを使用します。