xml、xsltから正しい結果を得るには？

Question

私はこの例を試してみたい：

ファイル：data.xmlの

<?xml version="1.0"?> 
<?xml-stylesheet type="text/xsl" href="Transform.xslt"?> 
<addressbook> 
    <address> 
    <first-name>Doris</first-name> 
    <last-name>Smith</last-name> 
    <city>New York</city> 
    <state>WI</state> 
    </address> 
    <address> 
    <first-name>Mary</first-name> 
    <last-name>Smith</last-name> 
    <city>Vancouver</city> 
    <state>MA</state> 
    </address> 

ファイル：Transform.xslt

<?xml version="1.0"?> 
<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:output method="text"/> 

    <xsl:template match="/"> 
    <xsl:text>Customers grouped by state&#xA;&#xA;</xsl:text> 
    <xsl:for-each-group select="/addressbook/address" group-by="state"> 
     <xsl:sort select="state"/> 
     <xsl:text> State = </xsl:text> 
     <xsl:value-of select="current-grouping-key()"/> 
     <xsl:text>&#xA;</xsl:text> 
     <xsl:for-each select="current-group()"> 
     <xsl:text>&#x9;</xsl:text> 
     <xsl:value-of select="(first-name, last-name)" separator=" "/> 
     <xsl:text>, </xsl:text> 
     <xsl:value-of select="city"/> 
     <xsl:text>&#xA;</xsl:text> 
     </xsl:for-each> 
    </xsl:for-each-group> 
    </xsl:template> 

</xsl:stylesheet> 

が予想される出力は次のとおりです。

Customers grouped by state 

    State = MA 
    Mary Smith, Vancouver 
    State = WI 
    Doris Smith, New York 

しかし私が持っているものは：

ドリス・スミスニューヨークWIメアリー・スミスバンクーバーMA

あなたは私に問題を説明することができれば、私は非常に感謝されます。

Answer 1

XMLファイルのxml-stylesheet処理命令に基づいて、ブラウザを使用してXSLTを処理しているようです。

残念ながら、Saxon-CEやSaxon-JSのようなものがなければ、ブラウザでXSLT 2.0の変換を実行することはできません。

はここで動作するはずMuenchian Groupingを使用してXSLT 1.0オプション...

XML入力

<?xml-stylesheet type="text/xsl" href="Transform.xslt"?> 
<addressbook> 
    <address> 
    <first-name>Doris</first-name> 
    <last-name>Smith</last-name> 
    <city>New York</city> 
    <state>WI</state> 
    </address> 
    <address> 
    <first-name>Mary</first-name> 
    <last-name>Smith</last-name> 
    <city>Vancouver</city> 
    <state>MA</state> 
    </address> 
</addressbook> 

XSLT 1.0（Transform.xslt）

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:key name="address" match="address" use="state"/> 

    <xsl:template match="/addressbook"> 
    <xsl:text>Customers grouped by state&#xA;&#xA;</xsl:text> 
    <xsl:for-each select="address[count(.|key('address',state)[1])=1]"> 
     <xsl:sort select="state"/> 
     <xsl:value-of select="concat('&#x9;',state,'&#xA;')"/> 
     <xsl:for-each select="key('address',state)"> 
     <xsl:value-of select="concat('&#x9;', 
      first-name,' ',last-name, 
      ', ',city,'&#xA;')"/> 
     </xsl:for-each> 
    </xsl:for-each> 
    </xsl:template> 

</xsl:stylesheet> 

です出力

Customers grouped by state 

    MA 
    Mary Smith, Vancouver 
    WI 
    Doris Smith, New York