は、そのタイプ

Question

ツバメI持って次

最初と最後の名前を取得するためのメソッドを持つPersonモジュールタイプ：name機能をPersonを拡張する

module type Person = sig 
    type t 
    val first : t -> string 
    val last : t -> string 
end 

PersonUtilsファンクタを：

module PersonUtils (Person: Person) : sig 
    type t 
    val name : t -> string 
end = struct 
    include Person 
    let name p = Person.first p^" "^Person.last p 
end 

とMainモジュールは、次のように

で

module Main : sig 
    type t 
    val name : t -> string 
end = struct 
    include PersonUtils(struct 
     type t = { 
     first: string; 
     last: string; 
     } 

     let first p = p.first 
     let last p = p.last 
    end) 
end 

、私は追加のloud_first_name機能を追加したい：私は署名し、モジュールに次の行を追加します。

module Main : sig 
    type t 
    val name : t -> string 

    (* New *) 
    val loud_first_name : t -> string 
end = struct 
    include PersonUtils(struct 
     type t = { 
     first: string; 
     last: string; 
     } 

     let first p = p.first 
     let last p = p.last 
    end) 

    (* New *) 
    let loud_first_name p = String.uppercase p.first 
end 

はしかし、loud_first_nameはもはや私の構造を知っていることを表示されませんtと入力して、エラーUnbound record field firstが残っています。

私の質問は、どうすればloud_first_nameのようなメソッドを作成して、自分のレコードフィールドにアクセスできるようにすることができますか？私はt型をレベルアップさせようとしましたが、私のファンクタの引数でそれを使うのは問題でした。

Answer 1

はtype nonrec t = tの組み合わせ（感謝Étienne Millon）のように見えるとを含みます、モジュールの署名がの場合、問題が修正されました。

module type PUSig = sig 
    type t 
    val name : t -> string 
end 

module PersonUtils (Person: Person) : PUSig with type t = Person.t = struct 
    include Person 
    let name p = Person.first p^" "^Person.last p 
end 

module Main : sig 
    type t = { 
    first: string; 
    last: string; 
    } 
    val loud_first_name : t -> string 
end = struct 
    type t = { 
    first: string; 
    last: string; 
    } 

    include (PersonUtils(struct 
      type nonrec t = t 
      let first p = p.first 
      let last p = p.last 
      end) : PUSig with type t := t) 

    (* New *) 
    let loud_first_name p = String.uppercase_ascii p.first 
end 

Answer 2

あなたのタイプが同じであることを示す必要があります。あなたのタイプが同じであれば、その情報は失われます。

module PersonUtils (Person: Person) : sig 
    type t = Person.t 
    val name : t -> string 
end 
= struct 
    include Person 
    let name p = Person.first p^" "^Person.last p 
end 

別のアプローチ（私はお勧めウィッヒは）あなたのモジュールタイプ宣言にwith句を追加することです。

module PersonUtils (Person: Person) : sig 
    type t 
    val name : t -> string 
end 
with type t = Person.t 
= struct 
    include Person 
    let name p = Person.first p^" "^Person.last p 
end 

情報は、署名宣言で直接見えないが、それはあなたが個別にあなたの署名とあなた数子を宣言することができます：

module type Personutils_T = sig 
    type t 
    val name : t -> string 
end 

module PersonUtils (Person: Person) : Personutils_T 
with type t = Person.t 
= struct 
    include Person 
    let name p = Person.first p^" "^Person.last p 
end