Perl6 :: Formで参照を使用するにはどうすればよいですか？

Question

Perl6::Formで表形式のデータを印刷しようとしていますが、ハッシュリファレンスからデータを出力する方法がわかりません。これまでに試したことは次のとおりです。

#!/usr/bin/perl 
use Perl6::Form; 

my @alerts; 

push @alerts, { site => "192.168.0.1", status => "200", id => "QWE" }; 
push @alerts, { site => "192.168.0.2", status => "500", id => "QER" }; 

print form 
     ' ====================================== ', 
     '| ID   | SITE | STATUS |', 
     '|-------------+------------+-----------|', 
     '| {[[[[[[[[[} |{[[[[[[[[[} | {>>>>>>>} |', 
      \@alerts{id}, \@alerts{site},\@alerts{status}, 
     ' ====================================== '; 

Answer 1

パラレルアレイが必要です。

my @ids  = map { $_->{id}  } @alerts; 
my @sites = map { $_->{site} } @alerts; 
my @statuses = map { $_->{status} } @alerts; 

print 
    form 
     '+=======================================+', 
     '| ID   | SITE  | STATUS |', 
     '|-------------+-------------+-----------|', 
     '| {[[[[[[[[[} | {[[[[[[[[[} | {>>>>>>>} |', 
     \@ids,  \@sites,  \@statuses, 
     '+=======================================+'; 

コードの重複を排除できます。

my %dbf; # Data by field 
for my $field (qw(id site status)) { 
    $dbf{$field} = [ map { $_->{$field} } @alerts ]; 
} 

print 
    form 
     '+=======================================+', 
     '| ID   | SITE  | STATUS |', 
     '|-------------+-------------+-----------|', 
     '| {[[[[[[[[[} | {[[[[[[[[[} | {>>>>>>>} |', 
     $dbf{id},  $dbf{site}, $dbf{status}, 
     '+=======================================+';