ワークブックを開いたり閉じたりしようとしています

Question

フィーダファイルを開き、そこからデータをコピーし、統合ファイルのファイルに貼り付けた後に、フィーダファイルを開いて閉じたいと思います。私はコードを実行した後も開いたままになる、統合されたファイルにVBAコードとモジュールを入れたいと思っています。これがはっきりしていればいいと思いますが、私はもっと具体的にしようとすることができます。

ファイルにもパスワードがありますが、この例のパスワードはMarrin18です。私はそれを開くことができませんでしたので、パスワードで開くために必要なものをコード化していません。

Sub consolDirectors() 

ExcelApplication.Open.Workbooks ("2018 Budget PL_HC_CAP - MarrinV1.xlsx") 
Workbooks("2018 Budget PL_HC_CAP - MarrinV1").Worksheets("Summary").Range("A1:AH227").Copy 
Workbooks("2018 Budget PL_HC_CAP - Total 802").Worksheets("Marrin").Range("A1:AH227").PasteSpecial xlPasteValues 
Workbooks("2018 Budget PL_HC_CAP - MarrinV1").Close 

End Sub 

Answer 1

Sub consolDirectors() 
    Const FPATH As String = "T:\Planning\FY Budget\2018 Budget\" & _ 
          "Director Templates\With updates\" 
    Const RNG_COPY As String = "A1:AH227" 
    Dim wb As Workbook 

    'you should use the full path here.... 
    Set wb = Workbooks.Open(_ 
      FileName:= FPATH & "2018 Budget PL_HC_CAP - MarrinV1.xlsx", _ 
      Password:= "passHere") 

    'add the file extension here - I'm guessing "xlsx" ? 
    Workbooks("2018 Budget PL_HC_CAP - Total 802.xlsx" _ 
     ).Worksheets("Marrin").Range(RNG_COPY).Value = 
     wb.Worksheets("Summary").Range(RNG_COPY).Value 

    'If this file is the one with the macro you can use ThisWorkbook instead 
    'ThisWorkbook.Worksheets("Marrin").Range(RNG_COPY).Value = _ 
    '   wb.Worksheets("Summary").Range(RNG_COPY).Value 

    wb.Close False 

End Sub 

Answer 2

あなたは内容を読み取るために、ブックを開く必要はありません。しかし、コンテンツセルをセルで書き込む必要があるので、これは欠点です。あなたはここで5秒マクロでOKであれば、それは次のようになります。

Option Explicit 

Sub Fd() 
    Dim FilePath$ 
    Dim i As Long, j As Long 
    Const FileName$ = "2018 Budget PL_HC_CAP - MarrinV1.xlsx" 
    Const SheetName$ = "Summary" 
    FilePath = "C:\mypath\" ' path to feeder file 2018 Budget PL_HC_CAP - MarrinV1.xlsx 

    DoEvents 
    Application.ScreenUpdating = False 
    If Dir(FilePath & FileName) = Empty Then 
     MsgBox "The file " & FileName & " was not found", , "File Doesn't Exist" 
     Exit Sub 
    End If 
    For i = 1 To 227 
     For j = 1 To 34 
      Cells(i, j) = GetData(FilePath, FileName, SheetName, Cells(i, j)) 
     Next j 
    Next i 
    ActiveWindow.DisplayZeros = False 
End Sub 

Private Function GetData(Path, File, Sheet, Rng) 
    Dim Data$ 
    Data = "'" & Path & "[" & File & "]" & Sheet & "'!" & Rng.Address(, , xlR1C1) 
    GetData = ExecuteExcel4Macro(Data) 
End Function 

Answer 3

@timウィリアムズ@Tehscriptここで私は、とてもではない進歩を使用して巻き取ったコードですが、両方のあなたの

Sub FeedFiles() 
    Workbooks.Open Filename:= "T:\Planning\FY Budget\2018 Budget\Director Templates\With updates\2018 Budget PL_HC_CAP - MarrinV1.xlsx", Password:="Marrin18" 
    Workbooks("2018 Budget PL_HC_CAP - MarrinV1.xlsx").Worksheets("Summary").Activate 
    Workbooks("2018 Budget PL_HC_CAP - MarrinV1.xlsx").Worksheets("Summary").Range("A1:AH227").Copy 
    Workbooks("2018 Budget PL_HC_CAP - Total 802.xlsm").Worksheets("Marrin").Range("A1:AH227").PasteSpecial xlPasteValues 
    Workbooks("2018 Budget PL_HC_CAP - MarrinV1.xlsx").Close 
End Sub