NSISインストーラのページごとに異なるヘッダービットマップを設定するにはどうすればいいですか？

Question

どのようにして、異なるページに異なるビットマップを設定できますか？たとえば、ライセンスページのヘッダーにビットマップを設定し、ディレクトリページのヘッダーに別のビットマップを設定しますか？

Answer 1

NSISは本当にこれを実行するように設計されていなかったが、前および/またはshowコールバック関数で微調整ページからあなたを止めるものは何もない。

!include MUI2.nsh 
!define MUI_HEADERIMAGE 

!insertmacro MUI_PAGE_WELCOME 

!define MUI_PAGE_CUSTOMFUNCTION_PRE resetimg 
!insertmacro MUI_PAGE_COMPONENTS 

!define MUI_PAGE_CUSTOMFUNCTION_PRE setdirimg 
!insertmacro MUI_PAGE_DIRECTORY 

!define MUI_PAGE_CUSTOMFUNCTION_PRE resetimg 
!insertmacro MUI_PAGE_COMPONENTS 

!insertmacro MUI_LANGUAGE "English" 

!macro fixheaderimgafterupdate 
;Ugly way to trigger a repaint 
GetDlgItem $0 $hwndparent 1046 
ShowWindow $0 0 
ShowWindow $0 1 
!macroend 

Function setdirimg 
File "/oname=$PLUGINSDIR\hdrdir.bmp" "${NSISDIR}\Contrib\Graphics\Header\orange.bmp" 
SetBrandingImage /IMGID=1046 "$PLUGINSDIR\hdrdir.bmp" 
!insertmacro fixheaderimgafterupdate 
FunctionEnd 

Function resetimg 
#SetBrandingImage /IMGID=1046 "$PLUGINSDIR\modern-header.bmp" ;This also works, but does not deal with stretching etc 
!insertmacro MUI_HEADERIMAGE_INIT "" 
!insertmacro fixheaderimgafterupdate 
FunctionEnd