DelphiでADOを使用してTBlobFieldからデータを読み込むには？

Question

私はTBlobFieldからTADOBlobStreamを使ってデータを読み込もうとしていました。私は次の関数

function DecompressBlobFieldCustom(AField:TBlobField):String; 
    var 
     BLOBStream:TADOBlobStream; 
     Size:Integer; 
    begin 
     BLOBStream:= TADOBlobStream.Create(AField,bmRead); 
     Size:= BLOBStream.Size; 
     BLOBStream.Read(Result,Size); 
    end; 

を書き、

Data := DecompressBlobFieldCustom(FldImage); 

を次のように私は関数を使用するが、私はif Length(Data) > 0 thenをしようとするとき、私はAccess violation at address XXXXエラーを取得しています。私は問題を理解できませんでした。助けてください。

Answer 1

Resultは文字列型ですが、ブロブストリームはバイト配列で動作します。通常、文字列であるかのようにバイト配列を扱うのは間違いです。さらに、エラーの実際の原因であるバッファを読み込みに割り当てることはありませんでした。 documentationで説明したように

function ReadBlobField(Field: TBlobField): TBytes; 
var 
    Stream: TStream; 
begin 
    Stream := TADOBlobStream.Create(Field, bmRead); 
    try 
    SetLength(Result, Stream.Size); 
    if Stream.Size>0 then 
     Stream.ReadBuffer(Result[0], Stream.Size); 
    finally 
    Stream.Free; 
    end; 
end; 

BLOBストリームを作成するTDataSetのCreateBlobStream方法を用いることが好ましい。このようなバイト配列に

読みます。したがって、コードは次のようになります。

function ReadBlobField(DataSet: TDataSet; Field: TField): TBytes; 
var 
    Stream: TStream; 
begin 
    Stream := DataSet.CreateBlobStream(Field, bmRead); 
    try 
    SetLength(Result, Stream.Size); 
    if Stream.Size>0 then 
     Stream.ReadBuffer(Result[0], Stream.Size); 
    finally 
    Stream.Free; 
    end; 
end; 

データは実際にはバイト配列であり、テキストを保持していないと仮定しています。それがブロブに保持されているという事実は、減圧と画像の言及と同様に、それを示唆している。

いくつかの他のコメント：

1. あなたがそれで終わっているときは、ストリームを破棄しなければなりません。
2. 一般に、ではなく、ReadBufferを使用することをお勧めします。これは、要求されたバイト数が読み取られない場合には、ReadBufferが例外を発生させるためです。