アセンブリ言語で文字列を入力する方法は？

Question

アセンブリ言語で文字列を入力する方法を知っている人はいませんか？私はint 21を使って文字を表示し入力しています。

Answer 1

function 0Ahを使用すると、バッファされた入力を読み取ることができます。

Byte 0 String length (0-255) 
Byte 1 Bytes read (0-255, filled by DOS on return) 
Bytes 2-..Length+2 (The character string including newline as read by DOS). 

列を読み出してバックユーザにそれをエコー表示小さなCOMファイルの例：

ds:dxの文字列バッファ与えられ、それはバッファレイアウトが長さ255までの文字列を読み取りますそれは入力行を上書きすること

org 0x100 

start: 
    push cs 
    pop ds ; COM file, ds = cs 

    mov ah, 0x0A ; Function 0Ah Buffered input 
    mov dx, string_buf ; ds:dx points to string buffer 
    int 0x21 

    movzx si, byte [string_buf+1] ; get number of chars read 

    mov dx, string_buf + 2 ; start of actual string 

    add si, dx ; si points to string + number of chars read 
    mov byte [si], '$' ; Terminate string 

    mov ah, 0x09 ; Function 09h Print character string 
    int 0x21 ; ds:dx points to string 

    ; Exit 
    mov ax, 0x4c00 
    int 0x21 

string_buf: 
    db 255 ; size of buffer in characters 
    db 0 ; filled by DOS with actual size 
    times 255 db 0 ; actual string 

ノート（と、それはそのプログラムが何をやっている見ていない可能性があります！）

別の方法としては、function 01hを使用して、ループ内の文字を自分で読むことができます。次のようなものがあります（255文字を超える文字が入力された場合は、あとでバッファオーバーフローします）。

org 0x100 

start: 
    push cs 
    pop ax 
    mov ds, ax 
    mov es, ax; make sure ds = es = cs 

    mov di, string ; es:di points to string 
    cld ; clear direction flag (so stosb incremements rather than decrements) 
read_loop: 
    mov ah, 0x01 ; Function 01h Read character from stdin with echo 
    int 0x21 
    cmp al, 0x0D ; character is carriage return? 
    je read_done ; yes? exit the loop 
    stosb ; store the character at es:di and increment di 
    jmp read_loop ; loop again 
read_done: 
    mov al, '$' 
    stosb ; 'Make sure the string is '$' terminated 

    mov dx, string ; ds:dx points to string 
    mov ah, 0x09 ; Function 09h Print character string 
    int 0x21 

    ; Exit 
    mov ax, 0x4c00 
    int 0x21 

string: 
    times 255 db 0 ; reserve room for 255 characters 

Answer 2

文字列は単なる一連の文字なので、ループ内でint 21コードを使用して一度に1文字ずつ文字列を取得できます。文字列を保持するラベルをデータセグメントに作成し、文字を読み取るたびにそのラベルにコピーします（毎回オフセットをインクリメントして文字が順番に格納されるようにします）。特定の文字が読み込まれたときにループを止める（おそらく入力する）。

これをすべて手作業で行うのは面倒です（バックスペースの仕組みについて考えてください）。また、stdio、stdlibなどとリンクしたり、ライブラリ関数を呼び出して多くの作業を行うことができます。