3つの名前のワークシートを検索する

Question

6より大きい数値を探して別のシートに送信する代わりに、 3つの名前を検索したいので、連絡先リストを検索し、その情報をシートからレポートシートにプルすることができます。私は3行目Stringの代わりLongされるべきだと思う

Private Sub CommandButton1_Click() 

Dim ws As Worksheet, myCounter 
Dim erow, myValue As Long 

For Each ws In Sheets 
    If ws.Range("C3").Value > 6 Then 
     myCounter = 1 
     ws.Select 
     ws.Range("c3").Select 

     myValue = ws.Range("C3").Value 
     Worksheets("Report").Select 
     erow = ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Row 
     ActiveSheet.Cells(erow, 1) = myValue 

     nextValue = MsgBox("Value found in " & ws.Name & Chr(10) & "Continue?", vbInformation + vbYesvbNo, ws.Name & " C3 = " & ws.Range("C3").Value) 
     Select Case nextValue 
      Case Is = vbYes 
      Case Is = vbNo 
       Exit Sub 
     End Select 
    End If 
Next ws 

If myCounter = 0 Then 
    MsgBox "None of the sheets contains a " & Chr(10) & "value greater than 6 in cell C3 ", vbInformation, "Not Found" 
End If 

End Sub 

：

は、以下の私の古いコードです。

私が探している名前は "David" "Andrea" & "Caroline"です。3回書いても、ループしてもわかりません。また、これらの名前のスプレッドシート全体を検索する方法もわかりません。

Answer 1

以下のコードは、すべてのワークシートのセル "C3"に "David"、 "Andrea"、 "Caroline"の名前を探します。すべての試合について、「レポート」ワークシートの列Aの最初の空の行にコピーされます。

注：完全qualifed CellsとWorksheetsを使用する代わりに、SelectとActiveSheetを使用する必要はありません。

コード

Option Explicit 

Private Sub CommandButton1_Click() 

Dim ws As Worksheet, myCounter As Long 
Dim erow As Long, myValue As Long 
Dim nextValue As Long 

For Each ws In ThisWorkbook.Sheets 
    With ws 
     Select Case .Range("C3").Value 
      Case "David", "Andrea", "Caroline" 
       myCounter = 1 ' raise flag >> found in at least 1 sheet 

       ' get first empty row in "Report" sheet 
       erow = Worksheets("Report").Cells(Worksheets("Report").Rows.Count, 1).End(xlUp).Offset(1, 0).Row 
       Worksheets("Report").Cells(erow, 1) = .Range("C3").Value 

       nextValue = MsgBox("Value found in " & .Name & Chr(10) & "Continue?", vbInformation + vbYesNo, .Name & " C3 = " & .Range("C3").Value) 
       Select Case nextValue 
        Case Is = vbYes ' <-- if you are not doing anything here, you don't need it >> maybe you don't need the entire `Select Case` here 
        Case Is = vbNo 
         Exit Sub 
       End Select 
     End Select ' Select Case .Range("C3").Value 
    End With 
Next ws 

If myCounter = 0 Then 
    MsgBox "None of the sheets contains the names " & Chr(10) & " 'David', 'Andrea', 'Caroline' in cell C3 ", vbInformation, "Not Found" 
End If 

End Sub 

---

コメント：

nextValue = MsgBox("Value found in " & .Name & Chr(10) & "Continue?", vbInformation + vbYesNo, .Name & " C3 = " & .Range("C3").Value) 
Select Case nextValue 
    Case Is = vbYes ' <-- if you are not doing anything here, you don't need it >> maybe you don't need the entire `Select Case` here 
    Case Is = vbNo 
     Exit Sub 
End Select 

あなたが全体を置き換えることができます：それはあなたが以下のSelect CaseにCase Is = vbYesの場合は何もしていないようですもの：

If MsgBox("Value found in " & .Name & Chr(10) & "Continue?", vbInformation + vbYesNo, .Name & " C3 = " & .Range("C3").Value) = vbNo Then 
    Exit Sub 
End If