デルファイは、バイナリツリー

Question

をしてください保存し、ロード、私はこの二分木構造を持っているとします

Type 
    TPMyTree = ^TMyTree; 
    TMyTree = Record 
     ID:Integer; 
     FullName:String[50];//<-------- fixed 
     addrs:String[50] // <----------- fixed 
     LeftT:TPMyTree; 
     RightT:TPMyTree; 
    end; 

私は保存してストリームからそれを読み込むことができますどのように？

Answer 1

ストリームで作業する場合、最も複雑な問題は可変長データを扱うことです。あなたの場合は、FullNameとaddrsです。これらのフィールドのタイプはStringであるためです。最も簡単な解決策は、DelphiのストリームリーダーとライターのヘルパークラスTReaderとTWriterを使用することです。これは文字列を扱う簡単な手段を提供するためです。他の点では、最も明白な解決策は、一度に1つのノードを再帰的にストリームに書き込むことです。

ブラウザウィンドウで書かれた警告、コード：

// This will save one node to the stream, using the TWriter helper. Takes 
// care of potential NIL's. 
procedure SaveBinaryTreeToStreamWriter(RootNode: TPMyTree; W: TWriter); 
begin 
    if Assigned(RootNode) then 
    begin 
     W.WriteBoolean(True); 
     W.WriteInteger(RootNode^.ID); 
     W.WriteString(RootNode^.FullName); 
     W.WriteString(RootNode^.addres); 
     SaveBinaryTreeToStreamWriter(RootNode^.LeftT, W); 
     SaveBinaryTreeToStreamWriter(RootNode^.RightT, W); 
    end 
    else 
    W.WriteBoolean(False); 
end; 

// This will read one NODE from the stream, using the TReader helper. 
// Uses the boolean "nil" marker saved by the writing routine to also 
// return "nil" if needed. 
function ReadBinaryTreeNodeFromReader(R: TReader):TPMyTree; 
begin 
    if R.ReadBoolean then 
    begin 
     Result := AllocMem(SizeOf(TMyTree)); 
     Result^.ID := R.ReadInteger; 
     Result^.FullName := R.ReadString; 
     Result^.addres := R.ReadString; 
     Result^.LeftT := ReadBinaryTreeNodeFromReader(R); 
     Result^.RightT := ReadBinaryTreeNodeFromReader(R); 
    end 
    else 
    Result := nil; 
end; 

// This simply creates the TWriter and then starts the recursive process of 
// writing the tree to stream. 
procedure SaveBinaryTreeToStream(RootNode: TPMyTree; Stream: TStream); 
var W:TWriter; 
begin 
    W := TWriter.Create(Stream, 128); 
    try 
    SaveBinaryTreeToStreamWriter(RootNode, W); 
    finally W.Free; 
    end; 
end;  

// This simply creates the TReader and then starts the recursive process of 
// reading the tree one node at a time: 
function ReadFromStream(Stream:TStream):TPMyTree; 
var R: TReader; 
begin 
    R := TReader.Create(Stream, 128); 
    try 
    Result := ReadBinaryTreeNodeFromReader(R); 
    finally R.Free; 
    end;  
end;