Excel-VBAすべてのワークシートをキャプチャするCommandButton Clickイベントを使用してユニバーサルコード

Question

ワークシートのコマンドボタンが押されたときに実行するコードがあります。私はuserformsのための同様のものを見たが、ワークシートのボタンを越えて（そ​​して限られた）働く何かを見つけることができない。私は次のコードでclsCmdButtonと呼ばれるクラスモジュールの作成限り持っている

：

は

Private WithEvents cmdButton As MSForms.CommandButton 

Private Sub cmdButton_Click() 
'code i want to run 
End Sub 

私は、私はすべてのワークシートをループする必要があると思うし、その上にコマンドボタンや新品同様intialiseそれぞれを見つけますクラスのinsance。これはWorkbook_Openイベントで行うことができますが、コード化する方法がわかりません。誰でも助けてくれますか？

ありがとうございます！

Answer 1

私はこのようにあなたのクラスを修正したい：

Private WithEvents m_ctlButton As MSForms.CommandButton 

Private Sub Class_Terminate() 

    Set m_ctlButton = Nothing 

End Sub 


Private Sub m_ctlButton_Click() 
'code i want to run 
End Sub 

Public Property Set Button(ctlButton As MSForms.CommandButton) 

    Set m_ctlButton = ctlButton 

End Property 

はのは、私は怠け者だとして、これはクラス1であると仮定しましょう。

Option Explicit 
Dim colButtons As Collection 
Sub hookButtons(ws As Object) 
    Dim oBtn As Class1 
    Dim obj As OLEObject 
    Set colButtons = New Collection 
    For Each obj In ws.OLEObjects 
     If TypeOf obj.Object Is MSForms.CommandButton Then 
      Set oBtn = New Class1 
      Set oBtn.Button = obj.Object 
      colButtons.Add oBtn 
     End If 
    Next 
End Sub 

をし、最終的に、はThisWorkbookモジュールに、この追加：

今新しいモジュールでこれを追加するには、そのシートがアクティブにせずにボタンをクリックすることはできませんので

Private Sub Workbook_Open() 
    hookButtons ActiveSheet 
End Sub 

Private Sub Workbook_SheetActivate(ByVal Sh As Object) 
    hookButtons Sh 
End Sub 

を常に、アクティブなシートのボタンだけをフックする方が簡単です。 sheetActivateイベントを使用すると、ブック内の他のコードで未処理のエラーが発生した場合に、より頻繁にリセットされることを意味するはずです。