パラメータのクエリでASPクラシック名前付きパラメータ：スカラー変数を宣言する必要があります

Question

ASPクラシックでパラメータ化クエリを作成しようとしていますが、壁に頭を打っているように感じ始めています。私は次のエラーを取得しています：

Must declare the scalar variable "@something".

私はハローラインが何をするかですが、多分私は何かが欠けてい誓う... ADOは疑問符を期待するために起こっている

<% OPTION EXPLICIT %> 
<!-- #include file="../common/adovbs.inc" --> 
<% 

    Response.Buffer=false 

    dim conn,connectionString,cmd,sql,rs,parm 

    connectionString = "Provider=SQLOLEDB.1;Integrated Security=SSPI;Data Source=.\sqlexpress;Initial Catalog=stuff" 
    set conn = server.CreateObject("adodb.connection") 
    conn.Open(connectionString) 

    set cmd = server.CreateObject("adodb.command") 
    set cmd.ActiveConnection = conn 
    cmd.CommandType = adCmdText 
    cmd.CommandText = "select @something" 
    cmd.NamedParameters = true 
    cmd.Prepared = true 
    set parm = cmd.CreateParameter("@something",advarchar,adParamInput,255,"Hello") 
    call cmd.Parameters.append(parm) 
    set rs = cmd.Execute 
    if not rs.eof then 
     Response.Write rs(0) 
    end if 


%> 

Answer 1

この場合、実際のパラメータ名の代わりに使用します。現時点では、SQL「select @something」は実際にはパラメータ化されません。パラメータとしてではなく、（宣言されていない）SQL変数として「@something」が表示されます。 CommandText行を次のように変更してください。

cmd.CommandText = "select ?" 

そして、あなたが探している結果が得られると思います。

幸運を祈る！

Answer 2

あなたのクエリが達成しようとしていることがわかりません。私はまた、選択リストにパラメータが許可されているかどうかはわかりません。 MSDNでは以前はクエリの中でパラメータが許可されていた場所について多少の記事を書いていましたが、今は見つからないようです。

OTTOMHでは、ADOにパラメータ値を指定しようとすると正しく表示されます。あなたがこのようなことをするならあなたの質問は実行されますか？

SELECT 1 FROM sometable WHERE somefield = @something 

Answer 3

ここに、SQLインジェクション攻撃を防ぐためのMSDNライブラリ記事のサンプルコードがあります。私は元のURLを見つけることができませんが、タイトルキーワード（ASPでのSQLインジェクションの予防）のグーグルでは、十分速くそこにあなたを取得する必要があります。この現実の例が役立つことを願っています。

strCmd = "select title, description from books where author_name = ?" 
Set objCommand.ActiveConnection = objConn 
objCommand.CommandText = strCmd 
objCommand.CommandType = adCmdText 
Set param1 = objCommand.CreateParameter ("author", adWChar, adParamInput, 50) 
param1.value = strAuthor 
objCommand.Parameters.Append param1 
Set objRS = objCommand.Execute() 

MSDNの以下のページの下部にある、特に名前付きパラメータを参照してください。

MSDN example

Answer 4

with server.createobject("adodb.command") 
    .activeConnection = application("connection_string") 
    .commandText = "update sometable set some_col=? where id=?" 
    .execute , array(some_value, the_id) 
end with