T-SQL：複数の列に文字列を区切る

Question

Ex。

Col 1: Col 2: Col 3: Col 4: 
| word1 | word2 | word3 | word | 

へ

Column 1: 
| word1 word2 word3 word4 | 

それが複数の列に文字列から別の単語やフレーズを分離することは可能ですか？文字列内のすべての単語とフレーズは、通常、二重スペースで区切られます。 CASTやINTERSECTのようにSQL Serverから既に使用できる事前定義済みの関数はありますか？それとも独自に作成する必要がありますか？

Answer 1

は、動的SQLバージョンです。あなたが最大の単語数を知らない場合、ジョンのあなたが望むものを達成するための主なテクニックは、分割文字列とピボット（または条件付き集計）です。一度に両方をやっているので、ジョンの方法はすばらしいショートカットです。あなたは単語数がnumbrに固定されていない場合は、動的なスクリプトを使用することができます

IF OBJECT_ID('tempdb..#TblName') IS NOT NULL 
    BEGIN 
     DROP TABLE #TblName 
    END 

CREATE TABLE #TblName (
    ID INT IDENTITY(1,1) 
    ,String VARCHAR(500) 
) 

INSERT INTO #TblName VALUES ('word1 word2 word3 word4'),('abcd efgh ijkl') 

DECLARE @NumWords INT 

SELECT @NumWords = ISNULL(MAX((LEN(String) - LEN(REPLACE(String,' ','')))/2 + 1), 0) 
FROM 
    #TblName 

DECLARE @i INT = 1 
DECLARE @SQL NVARCHAR(MAX) 

SET @SQL = ' 
SELECT 
    t.Id 
    ,t.String 
    ,c.* 
FROM 
    #TblName t 
    CROSS APPLY (
     SELECT 

      ' 
WHILE @i <= @NumWords 
BEGIN 
    SET @SQL = @SQL 
      + IIF(@i > 1,', ','') 
      + 'Column' + CAST(@i AS NVARCHAR(MAX)) + '1 = x.value (''/x[' + CAST(@I AS NVARCHAR(MAX)) + ']'',''varchar(max)'')' 

    SET @i = @i + 1 
END 

SET @SQL = @SQL + ' 
     FROM 
      (SELECT CAST(''<x>'' + REPLACE(String,'' '',''</x><x>'') + ''</x>'' as XML) x) a 
    ) c' 


EXECUTE (@SQL) 

Answer 2

CROSS APPLYとXMLの助けを借りてここに拡大しやすいおよび/または契約

Declare @YourTable table (id int,Column1 varchar(max)) 
Insert Into @YourTable values 
(1,'word1 word2 word3 word4'), 
(2,'some other words') 

Select A.ID 
     ,B.* 
From @YourTable A 
Cross Apply (
     Select Pos1 = xDim.value('/x[1]','varchar(max)') 
       ,Pos2 = xDim.value('/x[2]','varchar(max)') 
       ,Pos3 = xDim.value('/x[3]','varchar(max)') 
       ,Pos4 = xDim.value('/x[4]','varchar(max)') 
       ,Pos5 = xDim.value('/x[5]','varchar(max)') 
       ,Pos6 = xDim.value('/x[6]','varchar(max)') 
       ,Pos7 = xDim.value('/x[7]','varchar(max)') 
       ,Pos8 = xDim.value('/x[8]','varchar(max)') 
       ,Pos9 = xDim.value('/x[9]','varchar(max)') 
     From (Select Cast('<x>' + Replace(A.Column1,' ','</x><x>')+'</x>' as XML) as xDim) A 
     ) B 

戻り

Answer 3

、it'saサンプル：

IF OBJECT_ID('tempdb..#tb') IS NOT NULL DROP TABLE #tb 
CREATE TABLE #tb (id int,Column1 varchar(max)) 
insert Into #tb values 
(1,'word1 word2 word3 word'), 
(2,'w1 w2 w3 w4 w5 w6') 

DECLARE @Cols NVARCHAR(max),@sql nvarchar(MAX) 
DECLARE @MaxWordCount INT 
SELECT @MaxWordCount=MAX(LEN(t.Column1)-len(replace(t.Column1,' ',''))+1) from #tb as t 
    SELECT @Cols=ISNULL(@Cols+',','')+'[Col '+LTRIM(sv.number)+']' FROM master.dbo.spt_values as sv WHERE sv.Type='P' and sv.number BETWEEN 1 AND @MaxWordCount 

PRINT @Cols 
SET @sql='SELECT * from (
      SELECT t.*, w.* FROM #tb AS t 
      CROSS APPLY (VALUES (convert(XML, ''<n>'' + replace(t.Column1, '' '', ''</n><n>'') + ''</n>''))) x(c) 
      CROSS APPLY (SELECT ''Col '' + ltrim(row_number()OVER (ORDER BY getdate())) AS col 
           ,s.b.value(''.'', ''varchar(200)'') AS wd 
          FROM x.c.nodes(''n'') s(b)) w 
     ) a PIVOT (max(wd) for col in ('+@Cols+')) p' 
PRINT @sql 
EXEC(@sql) 
IF OBJECT_ID('tempdb..#tb') IS NOT NULL DROP TABLE #tb 

 
id Column1 Col 1 Col 2 Col 3 Col 4 Col 5 Col 6 
2 w1 w2 w3 w4 w5 w6 w1 w2 w3 w4 w5 w6 
1 word1 word2 word3 word word1 word2 word3 word NULL NULL 

Answer 4

これはどう？

Create Table AllData (Column0 varchar(500)) 
Insert Into AllData Values ('word1 word2 word3 word4') 
Select parsename(replace(replace(replace([Column0],' ',' '),' ',' '),' ','.'), 4) [Col1], 
parsename(replace(replace(replace([Column0],' ',' '),' ',' '),' ','.'), 3) [Col2], 
parsename(replace(replace(replace([Column0],' ',' '),' ',' '),' ','.'), 2) [Col3], 
parsename(replace(replace(replace([Column0],' ',' '),' ',' '),' ','.'), 1) [Col4] 

from AllData