2つのAround関数間でオブジェクトを渡す - AOP

Question

私はController、Service、およびDao層の監査を行っています。私はコントローラ、サービス、Daoの3つのAroundアスペクト機能を持っています。私はコントローラメソッド上に存在する場合、Aroundアスペクト関数を呼び出すカスタムアノテーションを使用します。注釈の中で私は、Controller Around関数からAspectクラス内のService around関数に渡したいプロパティを設定しました。

public @interface Audit{ 
    String getType(); 
} 

このgetTypeの値をインターフェイスから設定します。

@Around("execution(* com.abc.controller..*.*(..)) && @annotation(audit)") 
public Object controllerAround(ProceedingJoinPoint pjp, Audit audit){ 
    //read value from getType property of Audit annotation and pass it to service around function 
} 

@Around("execution(* com.abc.service..*.*(..))") 
public Object serviceAround(ProceedingJoinPoint pjp){ 
    // receive the getType property from Audit annotation and execute business logic 
} 

2つのAround関数間でオブジェクトを渡すにはどうすればよいですか？

Answer 1

アスペクトは、デフォルトではシングルトンオブジェクトです。しかし、あなたのようなユースケースで役立つ可能性のあるさまざまなインスタンス化モデルがあります。 percflow(pointcut)インスタンシエーションモデルを使用すると、コントローラ内の注釈の値をアドバイスの周りに保存し、アドバイスを中心にサービス内で取得することができます。以下はちょうどそれが次のようになります方法の例です：答えは正しいです

@Aspect("percflow(controllerPointcut())") 
public class Aspect39653654 { 

    private Audit currentAuditValue; 

    @Pointcut("execution(* com.abc.controller..*.*(..))") 
    private void controllerPointcut() {} 

    @Around("controllerPointcut() && @annotation(audit)") 
    public Object controllerAround(ProceedingJoinPoint pjp, Audit audit) throws Throwable { 
     Audit previousAuditValue = this.currentAuditValue; 
     this.currentAuditValue = audit; 
     try { 
      return pjp.proceed(); 
     } finally { 
      this.currentAuditValue = previousAuditValue; 
     } 
    } 

    @Around("execution(* com.abc.service..*.*(..))") 
    public Object serviceAround(ProceedingJoinPoint pjp) throws Throwable { 
     System.out.println("current audit value=" + currentAuditValue); 
     return pjp.proceed(); 
    } 

}