XDocument.Validate名前空間の問題

Question

私の問題を反映するために、MSDNの例を変更しました。

名前空間を使用しているとき、私は予想通りに文書を取得できません。また、名前空間を持たない文書の検証時に、エラーがあるかどうかに関係なく検証します。

Dim errors As Boolean = False 

Private Sub XSDErrors(ByVal o As Object, ByVal e As ValidationEventArgs) 
    Console.WriteLine("{0}", e.Message) 
    errors = True 
End Sub 

Private Function AddNameSpace(ByVal xDoc As XDocument, ByVal ns As XNamespace) As XDocument 
    For Each element As XElement In xDoc.Descendants 
     element.Name = ns + element.Name.LocalName 
    Next 
    Return xDoc 
End Function 

Sub Main() 
    Dim xsdMarkup As XElement = _ 
     <xsd:schema xmlns:xsd='http://www.w3.org/2001/XMLSchema' xmlns="http://somenamespace.com" targetNamespace="http://somenamespace.com"> 
      <xsd:element name='Root'> 
       <xsd:complexType> 
        <xsd:sequence> 
         <xsd:element name='Child1' minOccurs='1' maxOccurs='1'/> 
         <xsd:element name='Child2' minOccurs='1' maxOccurs='1'/> 
        </xsd:sequence> 
       </xsd:complexType> 
      </xsd:element> 
     </xsd:schema> 
    Dim schemas As XmlSchemaSet = New XmlSchemaSet() 
    schemas.Add("http://somenamespace.com", xsdMarkup.CreateReader) 

    Dim doc1 As XDocument = _ 
     <?xml version='1.0'?> 
     <Root> 
      <Child1>content1</Child1> 
      <Child2>content1</Child2> 
     </Root> 

    Dim doc2 As XDocument = _ 
     <?xml version='1.0'?> 
     <Root> 
      <Child1>content1</Child1> 
      <Child3>content1</Child3> 
     </Root> 

    Dim ns As XNamespace = "http://somenamespace.com" 
    doc1 = AddNameSpace(doc1, ns) 

    Console.WriteLine("Validating doc1") 
    errors = False 
    doc1.Validate(schemas, AddressOf XSDErrors) 
    Console.WriteLine("doc1 {0}", IIf(errors = True, "did not validate", "validated")) 

    Console.WriteLine() 
    Console.WriteLine("Validating doc2") 
    errors = False 
    doc2.Validate(schemas, AddressOf XSDErrors) 
    Console.WriteLine("doc2 {0}", IIf(errors = True, "did not validate", "validated")) 

End Sub 

出力：

検証DOC1

要素の名前空間の 'ルート' 'http://somenamespace.com' は無効な子要素の名前空間の 'CHILD1'「のhttp：// somenamespace .com '予想される要素のリスト： 'Child1'。

DOC1は

DOC2はあなたが名前空間を入れて、あなたのdoc1をしたい場合さてあなたは（xsd:schema要素に）自分のスキーマにelementFormDefault="qualified"を追加する必要があります

Answer 1

を検証

検証DOC2を検証しませんでした有効となる各要素に適用されます。あなたの現在のスキーマでは、有効なインスタンスはRootがtargetNamespaceにあるが、ChildX要素は名前空間にないインスタンスになります。

2番目の問題は、スキーマの検証と名前空間に関する既知の問題です。妥当性検証パーサーは、妥当性検査を行っていない妥当性検査がない場合、ルート要素の一致するスキーマを探します。 XmlReader APIを使用すると、その場合に警告が出されるように要求できますが、Validateメソッドを使用してその操作を行う方法はわかりません。したがって、コードは

Imports System 
Imports System.Xml 
Imports System.Xml.Linq 
Imports System.Xml.Schema 

Module Module1 

    Dim errors As Boolean = False 

    Private Sub XSDErrors(ByVal o As Object, ByVal e As ValidationEventArgs) 
     Console.WriteLine("{0}", e.Message) 
     errors = True 
    End Sub 

    Private Function AddNameSpace(ByVal xDoc As XDocument, ByVal ns As XNamespace) As XDocument 
     For Each element As XElement In xDoc.Descendants 
      element.Name = ns + element.Name.LocalName 
     Next 
     Return xDoc 
    End Function 

    Sub Main() 
     Dim xsdMarkup As XElement = _ 
      <xsd:schema xmlns:xsd='http://www.w3.org/2001/XMLSchema' xmlns="http://somenamespace.com" targetNamespace="http://somenamespace.com" elementFormDefault="qualified"> 
       <xsd:element name='Root'> 
        <xsd:complexType> 
         <xsd:sequence> 
          <xsd:element name='Child1' minOccurs='1' maxOccurs='1'/> 
          <xsd:element name='Child2' minOccurs='1' maxOccurs='1'/> 
         </xsd:sequence> 
        </xsd:complexType> 
       </xsd:element> 
      </xsd:schema> 
     Dim schemas As XmlSchemaSet = New XmlSchemaSet() 
     schemas.Add("http://somenamespace.com", xsdMarkup.CreateReader) 

     Dim doc1 As XDocument = _ 
      <?xml version='1.0'?> 
      <Root> 
       <Child1>content1</Child1> 
       <Child2>content1</Child2> 
      </Root> 

     Dim doc2 As XDocument = _ 
      <?xml version='1.0'?> 
      <Root> 
       <Child1>content1</Child1> 
       <Child3>content1</Child3> 
      </Root> 

     Dim ns As XNamespace = "http://somenamespace.com" 
     doc1 = AddNameSpace(doc1, ns) 

     Console.WriteLine("Validating doc1") 
     errors = False 
     doc1.Validate(schemas, AddressOf XSDErrors) 
     Console.WriteLine("doc1 {0}", IIf(errors = True, "did not validate", "validated")) 

     Console.WriteLine() 
     Console.WriteLine("Validating doc2") 
     Dim xrs As New XmlReaderSettings() 
     xrs.ValidationType = ValidationType.Schema 
     xrs.ValidationFlags = xrs.ValidationFlags Or XmlSchemaValidationFlags.ReportValidationWarnings 
     xrs.Schemas = schemas 
     AddHandler xrs.ValidationEventHandler, AddressOf XSDErrors 
     errors = False 
     Using xr1 As XmlReader = doc2.CreateReader() 
      Using xr2 As XmlReader = XmlReader.Create(xr1, xrs) 
       While xr2.Read() 

       End While 
      End Using 
     End Using 
     Console.WriteLine("doc2 {0}", IIf(errors = True, "did not validate", "validated")) 

    End Sub 

End Module 

のようになります