最後の行を選択し、VBでExcelでフォーマットします。

Question

スプレッドシートの最後の行に論理的にデータを挿入するユーザーフォームを作成しようとしていますが、データをドロップするとデータはフォーマットされません細胞。私の最初の考えは、データをドロップする前に、最後の行を選択してフォーマットすることだけです。この '.Autofit'プロパティはこのコードで機能しますが、他の設定、たとえば左揃えのテキストなど私は本当に必要、働かないでください。私は何が欠けていますか？ （。私は、これは複製を作成する知っているNDA上の理由から、「スタッフ」で、すべてのユーザーフォームのテキスト物事や変数を置き換え）

Private Sub StuffUpload_Click() 

Dim ws As Worksheet 

' Grabs the worksheet that the user is currently looking at, making this 
' form work on all sheets 
Set ws = ActiveSheet 

' Make sure all required fields have been entered 
If Stuff.Text = "" Then 
    MsgBox "You must enter Stuff." 
    Stuff.SetFocus 
    Exit Sub 
End If 

' Add a dash of formatting to the last row so the stuff we put into it will 
' look nice 
ws.Range("B" & Rows.Count).End(xlUp).Offset(1).Select 
With Selection 
    .HorizontalAlignment = xlLeft 
    .VerticalAlignment = xlBottom 
    .WrapText = True 
    .Orientation = 0 
    .AddIndent = False 
    .IndentLevel = 0 
    .ShrinkToFit = False 
    .ReadingOrder = xlContext 
    .MergeCells = False 
    .Rows.AutoFit 
End With 

' Adds the Stuff info into Col B at the Last Blank Row 
ws.Range("B" & Rows.Count).End(xlUp).Offset(1).Value = Me.Stuff.Value 
' Add date and time stamp for the moment the comment was entered 
ws.Range("C" & Rows.Count).End(xlUp).Offset(1).Value = Date + Time 
' Adds the Stuff info into Col D at the last Blank Row 
ws.Range("D" & Rows.Count).End(xlUp).Offset(1).Value = Me.Stuff.Value 


Unload Me 

End Sub 

Answer 1

は、以下のコードを使用してコードを交換してみてください：

Private Sub StuffUpload_Click() 

Dim ws As Worksheet 
Dim LastRow As Long 
Dim RngAnchor As Range 

' Grabs the worksheet that the user is currently looking at, 
' making this form work on all sheets  
Set ws = ActiveSheet 

' Make sure all required fields have been entered 
If Stuff.Text = "" Then 
    MsgBox "You must enter Stuff." 
    Stuff.SetFocus 
    Exit Sub 
End If 

' Add a dash of formatting to the last row so the stuff we put into it will 
' look nice 
With ws 
    LastRow = .Cells(.Rows.Count, "B").End(xlUp).Row ' get the last row in column "B" 

    ' set the anchor point of the range in column "B" 
    Set RngAnchor = .Range("B" & LastRow + 1) 

    ' Adds the Stuff info into Col B at the Last Blank Row 
    RngAnchor.Value = Me.Stuff.Value 

    ' Add date and time stamp for the moment the comment was entered 
    RngAnchor.Offset(, 1).Value = Now 

    ' Adds the Stuff info into Col D at the last Blank Row 
    RngAnchor.Offset(, 2).Value = Me.Stuff.Value '<-- already added this on Column "B" 

    ' now format last row, cells "B:D" 
    With RngAnchor.Resize(1, 3) 
     .HorizontalAlignment = xlLeft 
     .VerticalAlignment = xlBottom 
     .WrapText = True 
     .Orientation = 0 
     .AddIndent = False 
     .IndentLevel = 0 
     .ShrinkToFit = False 
     .ReadingOrder = xlContext 
     .MergeCells = False 
     .Rows.AutoFit 
    End With 

End With 

Unload Me 

End Sub