ハイブのデータ範囲に左結合を実装する方法

Question

下のオラクルロジックをハイブに変換したいと思います。 ロジック：

Select a.id,a.name,b.desc from table a left join table b on 
a.num between b.min_num and b.max_num; 

は、いずれかがハイブの上記のロジックを実現するために私を助けることができます。あなたは、パフォーマンス上のコントロールを持ってこのソリューションでは

Answer 1

select a.id 
     ,a.name 
     ,b.desc 

from    table_a as a 

     left join (select a.id 
          ,b.desc 

        from    table_a as a 
          cross join table_b as b 

        where a.num between b.min_num and b.max_num 
        ) b      

     on   b.id = 
        a.id 
; 

Answer 2

select a.id 
     ,a.name 
     ,b.desc 

from    table_a as a 

     left join (select b.min_num + pe.pos as num 
          ,b.desc 

        from table_b as b 
           lateral view 
            posexplode(split(space(b.max_num-b.min_num),' ')) pe 
        ) b      

     on   b.num = 
        a.num 
; 

Answer 3

。
b範囲はサブ範囲に分割されていて、希望通りに小さくなります（x）。

• あまりにも大きいxは、実質的にクロスジョインを引き起こします。
• 小さすぎるxは、b（x = 1はすべてbの範囲の値を生成します）から大きなセットを生成する可能性があります。

---

set hivevar:x=100; 

select a.id 
     ,a.name 
     ,b.desc 

from  table_a as a 

     left join 

      (select a.id 
        ,b.desc 

      from  table_a as a 

        inner join 

         (select b.min_num div ${hivevar:x} + pe.pos as sub_range_id 
           ,b.* 

         from  table_b as b 
           lateral view 
            posexplode(split(space(cast (b.max_num div ${hivevar:x} - b.min_num div ${hivevar:x} as int)),' ')) pe 
         ) as b 

        on   a.num div ${hivevar:x} = 
           b.sub_range_id 

      where a.num between b.min_num and b.max_num 
      ) b      

     on   b.id = 
        a.id 
;