まだマクロが正常に動作していても、「保護されたシートにこれを行うことはできませんか？

Question

だから私はこのコードが完成したと思っていましたが、シート1から他のシートに移動してからシート1に戻ると、msgboxがポップアップし、保護されていないことを通知しますシート。

私は、コードが想定していたとおりに正しく動作しているため、なぜこのようなことが起こっているのか不明です。どんな助けもありがとうございます。

編集：私はおそらくシートがパスワード "1"で保護されていると述べたはずです。私はこれが最も適切なパスワードではないことを認識しています。私はこの問題を解決するために、より簡単にアクセスできます。

Sub freezesheet() 
'set variable for the naming of the new sheet 
Dim newname As String 

'assignes our open variable to a designated value 
Sheets("Sheet1").Activate 
newname = Sheets("Sheet1").Range("C2").Value 

'copies the sheet to a new sheet after the designated tab 
Sheets("Sheet1").Copy after:=Sheets(3) 
ActiveSheet.Name = newname 

'unprotects the sheet so we can copy and paste as values 
ActiveSheet.Unprotect "1" 

'makes all of the formulas on the sheets into values and returns you to the original sheet 
Cells.Select 
    selection.Copy 
    selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _ 
     :=False, Transpose:=False 
    Application.CutCopyMode = False 

'Re-protects sheet to ensure that we don't make changes to historical data. 
ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True _ 
     , AllowFormattingCells:=True, AllowFormattingColumns:=True, _ 
     AllowFormattingRows:=True 

Sheets("Sheet1").Activate 

End Sub 

Answer 1

下記の再書き込みでは、いくつかの問題が解決されます。うまくいけばそれらの世話をして、サブは間違いなく実行する必要があります。すなわち：

• 同じ名前の既存のシートをチェックし
• 潜在的な衝突を回避するためには、クリップボード
• に大量のデータを置くことを避けるために.Valueを使用し
• 必要はありませんが、完全な範囲を認定する際の選択と有効化回避ThisWorkbook

を使用すると、詳細についてはコメントを参照してください

Sub freezesheet() 
    'set variable for the naming of the new sheet 
    Dim newname As String 
    'assigns newname variable to a designated value 
    newname = ThisWorkbook.Sheets("Sheet1").Range("C2").Value 
    ' Check if sheet name already exists 
    Dim sh as worksheet 
    On Error Resume Next 
    Set sh = ThisWorkbook.Sheets(newname) 
    On Error GoTo 0 
    If Not sh Is Nothing Then 
     MsgBox "Error: sheet name already exists, aborted" 
     Exit Sub 
    End If 
    'copies the sheet to a new sheet after sheet 3 
    ThisWorkbook.Sheets("Sheet1").Copy after:=Sheets(3) 
    With ThisWorkbook.Sheets(4) 
     .Name = newname ' New sheet was after sheet 3, so now sheet 4 
     'unprotects the sheet so we can copy and paste as values 
     .Unprotect "1" 
     'makes all of the formulas on the sheets into values 
     .UsedRange.Value = .UsedRange.Value 
     'Re-protects sheet to ensure that we don't make changes to historical data. 
     .Protect DrawingObjects:=True, Contents:=True, Scenarios:=True _ 
       , AllowFormattingCells:=True, AllowFormattingColumns:=True, _ 
       AllowFormattingRows:=True 
    End With 
    ThisWorkbook.Sheets("Sheet1").Activate 
End Sub