コレクションでjsonbuilderを使用するには？

Question

は、私はこのようなJSON形式のメッセージを作成する必要があります。

{ 
    success:true, 
    count:3, 
    data: [ 
    {id:1}, 
    {id:2}, 
    {id:3} 
    ] 
} 

私はこの

import groovy.json.* 

def tasks = [1, 2,3] 
def json = new JsonBuilder() 

json{ 
    success(true) 
    count(tasks.size()) 
    data { 
    tasks.each { 
     data(
     id: it   
    ) 
    } 
    } 
} 

JsonOutput.prettyPrint(json.toString()) 

を試してみましたが、それは動作しません。誰かが私にそれを動作させる方法を示すことができますか？

私は、フォーム [[id: 1], [id: 2], [id: 3]]のリストにタスクリストを変換し、それを「jsonizing」をお勧めしたい

Answer 1

：

import groovy.json.JsonBuilder 

def tasks = [1, 2, 3] 
def json = new JsonBuilder() 

json{ 
    success(true) 
    count(tasks.size()) 
    data(tasks.collect {[id: it]}) 
} 

println json.toPrettyString() 

私は通常（マップ、例えばリスト）最初Groovyでのデータ構造を生成することを好むし、 JSONに変換します。通常、シリアル化するデータをより詳細に制御でき、シリアル化コードにロジックを含める必要はありません。

import groovy.json.JsonBuilder 

def tasks = [1, 2, 3] 

def data = [ 
    success: true, 
    count: tasks.size(), 
    data: tasks.collect {[id: it]} 
] 

def json = new JsonBuilder(data) 
println json.toPrettyString()