ディレクトリ内のテキストファイルのディレクトリ名のテキストファイル名を変更するバッチファイル

Question

@Echo off&SetLocal EnableExtensions EnableDelayedExpansion 
cd "C:\Documents and Settings\John\Desktop\New\Interest\f2" 
Pushd "C:\Documents and Settings\John\Desktop\New\Interest\f2" 
Set Line#=26 
Set /A LOfs=24 -1, Len=34 - LOfs 
For %%A in (*.txt) do For /F "tokens=1* delims=:" %%B in (
    'Findstr /N ".*" "%%A" ^|Findstr "^%Line#%:"' 
) do if %errorlevel% == 0 Set "Line=%%C"&Ren "%%~fA" "!Line:~%LOfs%,%Len%! - %%A!"" 
Popd 

上記のテキストのある場所にあるファイルのファイル名を特定の位置に変更しようとしています。

26行目が空白の場合は何もせず、ファイル名を変更しないでください。

私はどこかで間違っていて、サークルで回っています。

誰でも手助けできますか？

ありがとうございます。

Answer 1

あなたのスクリプトがどのように失敗するかは明記していませんが、いくつかの潜在的な問題があります。私はまた、可能性のある単純化を見る。

• あなたは確かに両方CDとPUSHD
• 私は数値変数を取り除くと、実際のコードの数字リテラルが含まれてしまっを必要としません。必要に応じて、変数に戻すことができます。
• 外側にはループFORは必要ありません。 FINDSTRは、ファイル名にワイルドカードを使用すると複数のファイルを検索し、ファイル名に続けて:を出力します。したがって、/Nオプションを追加すると、出力はfilename:line#:textという形式になります。 2番目のFINDSTRを調整して、正しい行番号のみを返すことができます。
• 空白行を無視するだけでは不十分です。名前の変更は、23文字目以降に有効なファイル名文字が1つ以上ある場合にのみ有効です。ファイル名は:、*、?、/、\、<、>、または|を含めることはできません。 （私はいくつか見逃しているかもしれない）。私はFOR /FのdelimsとFINDSTRの検索を調整して補正しました。
• のような変数展開では、!が含まれ、遅延拡張が有効な場合は値が破損します。 !は、ファイル名に有効な文字です。したがって、遅延拡張はループ内でオンとオフを切り替える必要があります。

私はあなたが欲しいものをやると信じています。以下のコードは、リネームコマンドをエコーし​​ます。正しい結果が得られたら、renの前にECHOを削除します。

@echo off 
setlocal disableDelayedExpansion 
pushd "C:\Documents and Settings\John\Desktop\New\Interest\f2" 
for /f "tokens=1,3 delims=:*?\/<>|" %%A in (
    'findstr /n "^" "*.txt" ^| findstr "^[^:]*:26:.......................[^:*?\\/<>|]"' 
) do (
    set "old=%%A" 
    set "line=%%B" 
    setlocal enableDelayedExpansion 
    ECHO ren "!old!" "!line:~23,11! - !old!" 
    endlocal 
) 
popd 

Answer 2

DAVESにアンわずかに異なる方法：

@Echo Off 

Set "SrcDir=%UserProfile%\Desktop\New\Interest\f2" 
Set "Mask=*.txt" 
Set "Line#=26" 
Set "LOfs=23" 
Set "Len=11" 

If /I Not "%CD%"=="%SrcDir%" Pushd "%SrcDir%"2>Nul&&(Set _=T)||Exit/B 

For /F "Tokens=1-2* Delims=:" %%A In ('FindStr/N "^" "%Mask%" 2^>Nul' 
) Do If "%%B"=="%Line#%" If Not "%%~C"=="" (Set "Line=%%C" 
    SetLocal EnableDelayedExpansion 
    If Not "!Line:~%LOfs%,%Len%!"=="" (
     If Not Exist "!Line:~%LOfs%,%Len%! - %%A" (
      Ren "%%A" "!Line:~%LOfs%,%Len%! - %%A")) 
    EndLocal) 

If "_"=="T" PopD 

Answer 3

この方法はfindstr.exeを必要としたり、それを高速に実行する必要がありますので、setlocal/endlocalをトグルしません。また、for %%Aをfor /Fと組み合わせて、dirコマンドを変更した、すでに名前を変更したファイルを再処理することを回避します。また

@Echo off 
SetLocal EnableDelayedExpansion 

cd "C:\Documents and Settings\John\Desktop\New\Interest\f2" 
Set /A Line#=26, LOfs=24 -1, Len=34 - LOfs 

For /F "delims=" %%A in ('dir /A-D /B *.txt') do (

    rem Read the desired line from this file 
    (for /L %%i in (1,1,%Line#%) do set "Line=" & set /P "Line=") < "%%A" 

    if defined Line ECHO Ren "%%~fA" "!Line:~%LOfs%,%Len%! - %%A" 

) 

なお、このバッチファイルは、現在のディレクトリが自動的に回復される終了時に現在の1 setlocalコマンドが実行されたときに、そのpushd/popdコマンドはどちらか必要とされていません。