Tcl/tk - グリッドのウィンドウの高さと幅を取得し、相対的なテキストの高さを設定します。

Question

最初に高さの25％を占め、次は高さの75％を占める2つのテキストボックスを1つ作成します。

toplevel winの相対的な高さと幅を計算してテキストコマンドに渡そうとしましたが、動作しませんでした（wmジオメトリによって返される次元の単位がテキストコマンドに渡されたときと同じではないためです）

後に私のコードです：

toplevel .t 
wm geometry .t 1500x800+10+10 
update 
proc topAspect {args} { 
    regexp {(\d+)} $args -> relAspect 
    regexp {([^\d|%]+)} $args -> aspect 
    regexp {(.*)x(.*)[+-](.*)[+-](.*)} [wm geometry .t] -> width height x y 
    puts "width->$width height->$height x->$x y->$y" 
    switch -regexp [string tolower $aspect] { 
     x { 
      return [expr $x + $relAspect] 
     } 
     y { 
      return [expr $y + $relAspect] 
     } 
     w { 
      return [expr $width * $relAspect/100] 
     } 
     h { 
      return [expr $height * $relAspect/100] 
     } 
     default { 
      log::log error "Unsupported relative aspect $aspect cannot be determined for top level window" 
     } 
    } 
} 

text .t.text1 -height [topAspect -width 25%] -width [topAspect -width 99%] 
grid .t.text1 -sticky news 
text .t.text2 -height [topAspect -width 75%] -width [topAspect -width 99%] 
grid .t.text2 -sticky news 

私は、次の試したとき - それは私にいくつかのまともなGUI与えました：

text .t.text1 -height 20 -width [topAspect -width 99%] 
grid .t.text1 -sticky news 
text .t.text2 -height 20 -width [topAspect -width 99%] 
grid .t.text2 -sticky news 

をしかし、私はrelatiを使用したいですveオプション。それを動作させるには？

Answer 1

これを解決する最も簡単な方法は、適切な比率の重みと均一なグループを持つグリッドジオメトリマネージャを使用することです。ウィンドウのサイズを変更するとうまく動作します。 Tkはポリシー自体を知っており、あなたのためにそれを維持しています。 （内部的には、gridはかなり洗練された制約ソルバーである;。あなたはそれにいくつかの本当に複雑なものを行うことができます）

toplevel .t 
grid [text .t.text1 -bg red] -sticky news 
grid [text .t.text2 -bg green] -sticky news 

# The group name is just an arbitrary non-empty string. 
# So long as it is the same on the two rows it will work as desired. 
# The weights give a ratio of 1:3, i.e., 25% to one and 75% to the other. 

grid rowconfigure .t .t.text1 -weight 1 -uniform group1 
grid rowconfigure .t .t.text2 -weight 3 -uniform group1 

（あなたはTkの8.5を使用している場合は、rowconfigureに行を指定する必要があります）

Answer 2

textウィジェットの-heightと-widthオプションは、文字単位で表示され、画面単位では表示されません。フォントの幅と高さでさらに分割して修正することができます（私はそれらを以下の一定の値に設定します）。これは整数除算であることに注意してください。

おお、すべての正規表現...私はちょっときれいにしました、あなたはそれを取るか、それを残すことができます。

proc topAspect {aspect relAspect} { 
    set relAspect [string trimright $relAspect %] 
    scan [wm geometry .t] "%dx%d%d%d" width height x y 
    set fontWidth 15 
    set fontHeight 15 
    switch -regexp [string tolower $aspect] { 
     x { 
      return [expr {$x + $relAspect}] 
     } 
     y { 
      return [expr {$y + $relAspect}] 
     } 
     w { 
      return [expr {($width * $relAspect/100)/$fontWidth}] 
     } 
     h { 
      return [expr {($height * $relAspect/100)/$fontHeight}] 
     } 
     default { 
      log::log error "Unsupported relative aspect $aspect cannot be determined for top level window" 
     } 
    } 
} 

また、あなたは-heightと-widthの両方のためにtopAspectに引数として-widthを使用：私はそれが間違いだったと推定します。

text .t.text1 -height [topAspect -height 25%] -width [topAspect -width 99%] 
grid .t.text1 -sticky news 
text .t.text2 -height [topAspect -height 75%] -width [topAspect -width 99%] 
grid .t.text2 -sticky news 

それ以外の場合は、ドナルフェローズのソリューションをお勧めします。

ドキュメント： * (operator)、 + (operator)、 / (operator)、 expr、 for、 grid、 proc、 return、 scan、 set、 string、 switch、 text (widget)、 wmは、 Syntax of Tcl regular expressions

Answer 3

場所は、この場合には最高の働いていた - でも良く割合を差し出し、以下のサイズを変更するには：

place .t.text1 -in .t -relheight .25 -relwidth .98 -relx .003 -rely .003 
place .t.text2 -in .t -relheight .75 -relwidth .98 -relx .003 -rely .254 

は、誰もがグリッドに比べて、このアプローチでは見ている任意の落とし穴があります。

ありがとう