ExcelのVBAで特定の列を削除しているときにグラフを削除できません

Question

異なる条件に基づいていくつかの列を削除しようとしています。これらの列セットには、テーブルの下にそれぞれのチャートがあります。コードを行ごとに実行すると完全に機能しますが、完全なコードを実行するとテーブルでうまく動作しますが、その下のグラフはまったく削除されません。

source file

If oper(j) = "ABC" Then 

    wtemp.Sheets("Graphs").Range("A:H, Q:AF").Delete 

     ElseIf oper(j) = "XYZ" Then 

       wtemp.Sheets("Graphs").Range("A:P, Y:AF").Delete 

        ElseIf oper(j) = "KHG" Then 

          wtemp.Sheets("Graphs").Range("A:X").Delete 

        Else 

        wtemp.Sheets("Graphs").Range("I:AF").Delete 

End If 

Answer 1

A ChartObjectのPlacementプロパティは、その下にあるセルに取り付けられている方法を制御します。 XlPlacement Enumerationを参照してください。残りのチャートオブジェクト（完全に削除された列が削除された後）は、おそらくPlacement = xlFreeFloatingです。

ここでは、このような状況を処理するためのサブステップを示します。最初にPlacementの値をバッファしてから列の削除を実行し、元のPlacementの値を再設定します。

Public Sub DeleteColumnsAndCharts(ByVal pColumnsToDelete As Excel.Range) 
    On Error GoTo errHandler 

    Dim PlacementByChartName As Object 'Scripting.Dictionary 
    Dim chartsWorksheet As Excel.Worksheet 
    Dim chart As Excel.ChartObject 

    Set PlacementByChartName = CreateObject("Scripting.Dictionary") 
    Set chartsWorksheet = pColumnsToDelete.Worksheet 

    'Keep the original Placement values before changing them. 
    For Each chart In chartsWorksheet.ChartObjects 
     PlacementByChartName(chart.Name) = chart.Placement 
     chart.Placement = xlMoveAndSize 
    Next 

    'Should the Delete method below fail, the Recover section will leave the worksheet intact. 
    pColumnsToDelete.EntireColumn.Delete 

Recover: 
    On Error Resume Next 
    'Restore the original Placement values on the remaining chart objects. 
    For Each chart In chartsWorksheet.ChartObjects 
     chart.Placement = PlacementByChartName(chart.Name) 
    Next 
    Set chart = Nothing 
    Set chartsWorksheet = Nothing 
    Set PlacementByChartName = Nothing 
    Exit Sub 

errHandler: 
    MsgBox Err.Description, vbExclamation + vbOKOnly, "Error" 
    Resume Recover 
End Sub 

あなたはこのようにそれを呼び出すことができます。

DeleteColumnsAndCharts wtemp.Sheets("Graphs").Range("A:X")