vbaチャートの動的データ範囲

Question

以下のコードは正しく動作しています。しかし、私のクエリは：--- 現在、私はA1からP4までの入力データシートの値を持っていますが、それは変更することができます。例えば、datavalueはA1からS7までです。 （データは常にExcelシートでAで始まります） しかし、以下のコードでは、手動で範囲を指定しました。レンジの部分で何をする必要があるのですか？自動的に列の範囲がわかります。

  Sub to_Draw_chart() 
       Dim ws_InputSheet As String 
       ws_InputSheet = "Sheet3" 
       Charts.Add 
       ActiveChart.ChartType = xlColumnStacked 
       ActiveChart.SetSourceData Source:=Sheets(ws_InputSheet).Range(ws_InputSheet & "!$A$1:$P$4"), PlotBy:=xlColumns 
       With ActiveChart 
        .HasTitle = True 
        .ChartTitle.Characters.Text = "Time_Plotter" 
        .Axes(xlValue).MaximumScale = 1000 
        .Axes(xlValue).MajorUnit = 250 
        .Axes(xlCategory).CategoryType = xlCategoryScale 
        .Axes(xlCategory).CategoryType = xlAutomatic 
       End Sub 

Answer 1

アクティブな選択からチャートを作成します、私はあなたが従うことsimplier以下のコードを見つけることだと思う：

Option Explicit 

Sub to_Draw_chart() 

    Dim ws_InputSheet As Worksheet, ws_OutputSheet As Worksheet 
    Dim dataRng As Range 

    Set ws_InputSheet = ThisWorkbook.Sheets("Sheet3") 

    With ws_InputSheet 
     Set dataRng = .Range("A1").CurrentRegion 
    End With 

    Charts.Add 
    ActiveChart.ChartType = xlColumnStacked 

    ActiveChart.SetSourceData Source:=dataRng, PlotBy:=xlColumns 
    With ActiveChart 
     .HasTitle = True 
     .ChartTitle.Characters.Text = "Time_Plotter" 
     .Axes(xlValue).MaximumScale = 1000 
     .Axes(xlValue).MajorUnit = 250 
     .Axes(xlCategory).CategoryType = xlCategoryScale 
     .Axes(xlCategory).CategoryType = xlAutomatic 
    End With 

End Sub 

Answer 2

以下のコードを試してみてください。この

Option Explicit 

Sub to_Draw_chart() 
    Dim ws_InputSheet As String, ws_OutputSheet As String 

    ws_InputSheet = "Sheet3" 

    Dim dataRng As Range 
    With Worksheets(ws_InputSheet) 
     Set dataRng = .Range("A1").CurrentRegion 
    End With 

    Charts.Add 
    ActiveChart.ChartType = xlColumnStacked 
' ActiveChart.SetSourceData Source:=Sheets(ws_OutputSheet).Range(ws_InputSheet & "!$A$1:$P$4"), PlotBy:=xlColumns 
    ActiveChart.SetSourceData Source:=Sheets(ws_OutputSheet).Range(dataRng.Address(True, True, True, True)), PlotBy:=xlColumns 
    With ActiveChart 
     .HasTitle = True 
     .ChartTitle.Characters.Text = "Time_Plotter" 
     .Axes(xlValue).MaximumScale = 1000 
     .Axes(xlValue).MajorUnit = 250 
     .Axes(xlCategory).CategoryType = xlCategoryScale 
     .Axes(xlCategory).CategoryType = xlAutomatic 
    End With 
End Sub 

Answer 3

を試してみてください。これは私があなたのws_InputSheetが、As WorkSheetを使用

Sub to_Draw_chart() 
    Dim ws_InputSheet As String 
    Dim SelRange As Range 
    Sheets("Sheet3").Activate 
    Set SelRange = Selection 
    ws_InputSheet = "Sheet3" 
    Charts.Add 
    ActiveChart.ChartType = xlColumnStacked 
    ActiveChart.SetSourceData Source:=SelRange, PlotBy:=xlColumns 
    With ActiveChart 
     .HasTitle = True 
     .ChartTitle.Characters.Text = "Time_Plotter" 
     .Axes(xlValue).MaximumScale = 1000 
     .Axes(xlValue).MajorUnit = 250 
     .Axes(xlCategory).CategoryType = xlCategoryScale 
     .Axes(xlCategory).CategoryType = xlAutomatic 
    End With 
End Sub