入れ子選択のSparql構文エラー

Question

人口が最も多い都市を選択しようとしています。私のクエリは次のようになります。

PREFIX dct: <http://purl.org/dc/terms/> 
PREFIX dbpedia: <http://dbpedia.org/resource/> 
PREFIX db: <http://dbpedia.org/> 
PREFIX dbp: <http://dbpedia.org/property/> 
PREFIX dbc: <http://dbpedia.org/resource/Category:> 
PREFIX dbo: <http://dbpedia.org/ontology/> 

SELECT ?population ?capital 
WHERE { 

    ?x dct:subject dbc:Countries_in_Europe . 
    ?x dbo:capital ?capital . 
    ?capital dbo:populationTotal ?population . 

    FILTER (?population = 
     (
      SELECT MAX(?popul) AS ?pop 
      WHERE{ 
       ?capital dbo:populationTotal ?popul . 
      } 
     ) 
) 

} 
LIMIT 200 

私はapacheの-イエナ-布石-2.4.0を使用して、構文エラー Encountered " "select" "SELECT "" at line 18, column 1. 問題がある任意のアイデアを取得していますThis PDF 5ページ を追っhaved？

Answer 1

SELECTクエリの結果をFILTER内の変数にバインドすることができますが、それはまったく間違っています。これはSQLでは機能しますが、SPARQLでは機能しません。

PREFIX dbo: <http://dbpedia.org/ontology/> 
PREFIX dbp: <http://dbpedia.org/property/> 
PREFIX dct: <http://purl.org/dc/terms/> 
PREFIX dbc: <http://dbpedia.org/resource/Category:> 
PREFIX dbpedia: <http://dbpedia.org/resource/> 
PREFIX db: <http://dbpedia.org/> 

SELECT ?population ?capital 
WHERE 
    { ?x  dct:subject   dbc:Countries_in_Europe ; 
       dbo:capital   ?capital . 
    ?capital dbo:populationTotal ?population 
    FILTER (?population = ?pop) 

    # sub-SELECTs are evaluated first and encapsulated by { } 
    # in addition (as to TomP's comment), you have to restrict to European captials here 
    { SELECT (MAX(?popul) AS ?pop) 
     WHERE 
     { ?x  dct:subject   dbc:Countries_in_Europe ; 
        dbo:capital   ?capital . 
      ?capital dbo:populationTotal ?popul } 
    } 
    } 
LIMIT 200 

しかし、あなたが本当にあなたのタスクを反映して、より簡単かつ明白な方法を使用していない理由は、「最高の人口を持つヨーロッパで資本」を持つようにしたい場合は、すなわちORDER BY + LIMIT 1：

PREFIX dbo: <http://dbpedia.org/ontology/> 
PREFIX dbp: <http://dbpedia.org/property/> 
PREFIX dct: <http://purl.org/dc/terms/> 
PREFIX dbc: <http://dbpedia.org/resource/Category:> 
PREFIX dbpedia: <http://dbpedia.org/resource/> 
PREFIX db: <http://dbpedia.org/> 

SELECT ?population ?capital 
WHERE 
    { ?x  dct:subject   dbc:Countries_in_Europe ; 
       dbo:capital   ?capital . 
    ?capital dbo:populationTotal ?population  
    } 
ORDER BY DESC(?population) 
LIMIT 1