削除ループのランタイムエラー

Question

以下のコードでランタイムエラータイプの不一致が発生する理由は何ですか？ if文に問題があるようです。

ランタイムエラーは、あなたの助けのための

Dim rng As Range 
Dim cell_search As Range 
Dim del As Range 
Dim FrRngCount As Range 
Dim I As Integer 
Dim DatatoData As Worksheet 

Set DatatoData = ThisWorkbook.Worksheets("PCA DATA2") 

Set FrRngCount = DatatoData.Range("A:A") 
I = Application.WorksheetFunction.CountA(FrRngCount) 

Set rng = Intersect(DatatoData.Range("CV2:CV" & I), DatatoData.UsedRange) 

For Each cell_search In rng 
If (cell_search.Value) = "Not in Range" Then 
    If del Is Nothing Then 
     Set del = cell_search 
    Else: Set del = Union(del, cell_search) 
    End If 
End If 
Next cell_search 
On Error Resume Next 
del.EntireRow.Delete 

おかげ型の不一致です。ピート

Answer 1

rngがNothingに設定されていますか？これを試してみてください：

Option Explicit 

Sub Test() 

Dim rng As Range 
Dim cell_search As Range 
Dim del As Range 
Dim FrRngCount As Range 
Dim I As Integer 
Dim DatatoData As Worksheet 

Set DatatoData = ThisWorkbook.Worksheets("PCA DATA2") 

Set FrRngCount = DatatoData.Range("A:A") 
I = Application.WorksheetFunction.CountA(FrRngCount)  

Set rng = Intersect(DatatoData.Range("CV2:CV" & I), DatatoData.UsedRange) 

If Not rng Is Nothing Then 

For Each cell_search In rng 
    cell_search.Activate 
    If cell_search.Value = "Not in Range" Then 
     If del Is Nothing Then 
      Set del = cell_search 
     Else: Set del = Union(del, cell_search) 
     End If 
    End If 
Next cell_search 

End If 

On Error Resume Next 
del.EntireRow.Delete 

End Sub 

これは私が持っているものであり、動作するようです。私は、デバッグのためにcell_search.Activeを追加しました。これを試して、エラーが発生したときにどのセルがアクティブになっているかを確認する必要があります。

Answer 2

上記のコメント（エラーが発生した場合）に基づいて、そのセルの.Valueを特定できないようです。エラーが発生するセルに数式がある場合（例：#DIV/0!または#NAME?または#Ref!）、これが該当します。

だから、私はあなたがそれを評価する前に、まずあなたがセルの.Valueをテストすることをお勧めしたい：

For Each cell_search In Rng 
    If IsError(cell_search.Value) Then 
     'What should happen in this case? 
    Else 
     If (cell_search.Value) = "Not in Range" Then 
      If del Is Nothing Then 
       Set del = cell_search 
      Else: Set del = Union(del, cell_search) 
      End If 
     End If 
    End If 
Next cell_search 

これはあなたのための問題を解決する場合は私に知らせてください。