Rはis.element（）に相当するSAS

Question

今日私はsasを開いたのは初めてで、同僚が書いたコードを見ています。

私はいくつかのデータ（import）が重複しているとしましょうが、私はVTNRという名前のユニークな番号を持つものだけを必要としているとしましょう。

まず彼女は、固有の番号を探します。

data M.import; 
    set M.import; 

    by VTNR; 
    if first.VTNR=1 then unique=1; 
    run; 

それから彼女は、重複番号を持つテーブルを作成します。すべての重複と

data M.import_dup1; 
    set M.import; 

    where unique^=1; 
    run; 

そして最後にテーブル。 しかし、ここでは、彼女は本当に例えばので、番号をハードコーディングされています

data M.import_dup2; 
    set M.import; 
    where VTNR in (130001292951,130100975613,130107546425,130108026864,130131307133,130134696722,130136267001,130137413257,130137839451,130138291041); 
    run; 

私はより良い方法がなければならないと確信しています。

私は私のようなもの書くとRとの唯一のよく知っているので：私は推測

import_dup2 <- subset(import, is.element(import$VTNR, import_dup1$VTNR)) 

をSASにも$のようなものがなければなりませんか？

Answer 1

VTNR値ごとに複数の観測値を持つIMPORTでは、最初に他のテーブルを作成する必要はありません。

data import_dup2 ; 
    set import; 
    by VTNR ; 
    if not (first.VTNR and last.VTNR); 
run; 

Answer 2

上記のソリューションでは重複はありますが、固有の値は得られません。 SASで両方を実行する方法はたくさんあります。非常に理解しやすいSQLソリューションです。

proc sql; 
create table no_duplicates as 
    select * 
     from import 
     group by VTNR 
     having count(*) = 1 
    ; 
create table all_duplicates as 
    select * 
     from import 
     group by VTNR 
     having count(*) > 1 
    ; 
quit; 

Answer 3

data want; 
    set import; 
    where VTNR in import_dup1; 
run; 

Answer 4

私はPROCのSORTのオプションを使用します。 OUT =データセットを指定しないと、元のデータを上書きしません。 Rコードの最も直接的な翻訳

import_dup2 <- subset(import, is.element(import$VTNR, import_dup1$VTNR)) 

は、SQLコード

proc sql; 
create table import_dup2 as 
    select * from import 
    where VTNR in (select VTNR from import_dup1) 
; 
quit; 

を用いることであろうようにしかし、あなたの目的がで観測を見つけることであれば、それは見えます私に

/*Generate fake data with dups*/ 
data class; 
set sashelp.class sashelp.class(obs=5); 
run; 

/*Create unique and dup dataset*/ 
proc sort data=class nouniquekey uniqueout=uniquerecs out=dups; 
by name; 
run; 

/*Display results - for demo*/ 
proc print data=uniquerecs; 
title 'Unique Records'; 
run; 

proc print data=dups; 
title 'Duplicate Records'; 
run; 

Answer 5

私はReezaのかトムのソリューションを使用することになりますが、完全を期すために、ソリューションR（とあなたの既存のコード）に似最もは、次の3つの手順になります。繰り返しますが、私はここでこれを使用しません。より簡単にできることのための余分な作業ですが、このコンセプトは他の状況で役立ちます。

最初に、重複のデータセットを取得します（彼女の方法、またはproc sort）。

proc sql; 
    select byvar 
    into :duplist separated by ',' 
    from dups; 
quit; 

は、その後、あなたが&duplist.でそれらを持っているので、同じようにそれらを使用することができます：uniqueoutとDupoutとのprocソートで

data want; 
    set have; 
    if not (byvar in &duplist.); 
run;