別のセッションからリモートSASワークライブラリを参照する

Question

SASセッションに問題はありましたが、リモートワークライブラリ（RWORK）に重要なファイルがあるためセッションを終了できませんでしたか？

私は確かに持っています！では、別の（新しい）セッションからそのライブラリにどのようにアクセスしますか？

Answer 1

あなたが所有するすべてのリモート作業ディレクトリに複数のlibrefを割り当てるためのマクロは次のとおりです。

 
rsubmit ; 

%MACRO DOUBLELIB(USER=&SYSUSERID,LIB=double)/des="Assign libname of double for multiple SAS sessions for the same user"; 

options nosymbolgen nomprint ; 

%LET WRK  = %SYSFUNC(pathname(work)) ; 
%LET WRKDIR = %SYSFUNC(scan(&WRK,-1,/)) ; 
%LET SASTEMP = %SYSFUNC(tranwrd(&WRK,&WRKDIR,)) ; 

filename mywork pipe "ls -ls &SASTEMP" ; 
data zwork ; 
    infile mywork lrecl=512 recfm=v pad ; 
    input @1 char $512. ; 
    if index(upcase(char),upcase("&USER")) and ^index(char,scan("&WRK",-1,'/')) and index(char,'SAS_work'); 
    path = scan(char,-1,' ') ; 
    n + 1 ; 
    call symput('PATH'||compress(n),"&SASTEMP"||strip(path)) ; 
    call symput('PATHN',compress(n)) ; 
run ; 

%NOBS(zwork) ; 
%IF &NOBS > 0 %THEN %DO ; 
    libname &LIB (
    %DO I = 1 %TO &PATHN ; 
     "&&PATH&I" 
    %END ; 
    ) access=readonly ; 
%END ; 
options symbolgen mprint ; 
%MEND DOUBLELIB; 

%DOUBLELIB(LIB=dblwork) ; 

endrsubmit ; 

/* Assign local libref to new remote dblwork libref */ 
libname rdouble slibref=dblwork server=myserver ; 

Answer 2

答えを知っている質問をする倫理がわからないのですが、うまくいけば他の人がこれを見つけるでしょう。

%macro serverpath; 
%put NOTE:; %put NOTE-; %put NOTE-; 
%put NOTE- libname OldWork "%sysfunc(pathname(RWORK))" server= remote %str(;); 
%put NOTE- rsubmit%str(;); 
%put NOTE- libname OldWork "%sysfunc(pathname(RWORK))"%str(;); 
%mend; %serverpath; 

これにより、必要なコードがログに記録されます。あなたが変更する必要があるかもしれないビットは、サーバー=オプションです - これはあなたがログオンしている環境の名前でなければなりません（プログラムでこれをどのように参照するかわかりません - 誰にも分かりません）

当然のことながら、

Answer 3

Chris Jさんへの返信 - missing macro ..

rsubmit ; 
%macro nobs(dsn); 
%local dsnid rc; 
%global nobs; 
%let nobs=.; 
%* open the data set of interest ; 
%let dsnid=%sysfunc(open(&dsn)); 
%* If the open was successful get the nobs and CLOSE &dsn ; 
%if &dsnid %then %do; 
    %let nobs=%sysfunc(attrn(&dsnid,nlobs)); 
    %let rc =%sysfunc(close(&dsnid)); 
%end; %else %do; 
    %put WARNING: Unable to open &dsn - %sysfunc(sysmsg()); 
    %let nobs=0; 
%end; %mend nobs; 
endrsubmit;